VBA-ээр дамжуулан олон үгийн баримтыг нэг дор хурдан нэгтгэх 2 арга

Энэ нийтлэлд бид олон Word баримт бичгүүдийг VBA-ээр нэг дор хурдан нэгтгэх 2 аргыг хуваалцаж байгаадаа баяртай байна.

Word дээр хэрэглэгчид хэд хэдэн баримт бичгийг нэгтгэх эсвэл нэгтгэхэд туслах анхдагч суулгагдсан шинж чанар байдаг. Дэлгэрэнгүй мэдээллийг энэ нийтлэлд тайлбарласан болно: Олон үгийн баримтыг хэрхэн яаж нэгтгэх вэ?

Энэ аргын тусламжтайгаар та хоёр товшилт хийх хэрэгтэй бөгөөд дараагийн баримт бичгийн агуулга өмнөхийнхөөс яг дараа гарч ирнэ. Тиймээс бид танд үүнийг хурдан хийх арга замыг санал болгож байна.

Арга 1: Сонгосон баримт бичгүүдийг нэгтгэх

1. Юуны өмнө шинэ хоосон баримт бичиг үүсгэнэ үү.
2. VBA-ийн редакторыг Word дээр “Alt + F11” товчийг дарж ажиллуулна уу.
3. Дараа нь "Хэвийн" дээр дарна уу.
4. Дараа нь "Оруулах" дээр дарна уу.
5. Мөн "Модуль" -ыг сонгоорой.
6. Шинэ модуль дээр давхар товшоод засах зайг нээнэ үү.
7. Дараахь макроыг наана уу:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Дараа нь "Run" дээр дарна уу эсвэл "F5" дээр дарна уу.
9. Одоо "Browse" цонхонд "Ctrl" товчийг дарж олон файл сонгоод "OK" дээр дарна уу.
10. Дараа нь сонгосон файлуудын бүх агуулгыг шинэ баримт бичигт нэгтгэх бөгөөд баримт бичиг бүрийн текстийг шинэ хуудаснаас эхлэнэ.

Тайлбар:

Бидний дурьдсанчлан энэхүү макро нь баримт бичиг бүрийн текстийг шинэ хуудсанд байрлуулдаг. Гэхдээ хэрэв танд эдгээр нь ар араасаа дараалан байх шаардлагатай бол та макро дээрх зарим кодын мөрүүдийг өөрчилж болно. “If nEachSelectedFile <nTotalFiles then” гэсэн мөрийг хайж олоход, дараачийн зургаан мөрийг олоход л хангалттай.

Арга 2: Фолдерт байгаа бүх баримт бичгүүдийг нэгтгэх

Хэрэв танд хавтсан хавтастай файл байгаа бол энэ макро маш сайн ажиллах болно.

1. Эхлэхийн тулд 1-р аргад тайлбарласны дагуу макро суулгаж, ажиллуулна уу.
2. Дараа нь макрог дараахаар солино уу:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. "Run" дээр дарж макро ажиллуулна уу.
4. Дараа нь та "Browse" цонх нээгдэх болно. Бүх баримт бичгийг хадгалах фолдероо сонгоно уу. Тэгээд "OK" дээр дарна уу.

Үүнтэй адилаар, баримт бичиг бүрийн текстүүд шинэ хуудаснаас эхэлдэг. Тэдгээрийг нэг нэгээр нь наалдуулахын тулд “.InsertBreak Type:=wdPageBreak” код мөрийг олж устгана уу.

Үг баримтаа зөв хамгаалаарай

Word баримт бичгүүдийг хамгаалах хамгийн сайн аргуудын нэг бол тэдгээрийг байнга нөөцлөх явдал юм. Нөөцлөлтийг гартаа авснаар та өгөгдөл алдахаас хэзээ ч эмээхгүй болно. Үүнээс гадна, хэрэгсэл авах нь зүйтэй засвар docx хэрэв тэдгээрийн аль нэг нь гэмтсэн байвал.

Зохиогчийн танилцуулга:

Вера Чен бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. эвдэрсэн Excel болон pdf програм хангамжийн бүтээгдэхүүнийг засах. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com