Outlook-ийн даалгаврын жагсаалтыг өөр өөр ангиллаар өөр хуудсанд хэвлэх 2 арга

Хэрэв та Outlook даалгаварт янз бүрийн өнгөний ангиллыг хуваарилж өгсөн бол одоо өөр өөр категори бүхий даалгаврын жагсаалтыг өөр хуудсанд хэвлэхийг хүсч байвал та энэ нийтлэлийг үзэх боломжтой. Энд бид танд үүнийг олж авах 2 аргыг хуваалцах болно.

Даалгавраа ангилах, сайн удирдахын тулд өнгөт ангиллыг даалгаварт хэрэглэсэн байх. Одоо, та даалгаврынхаа жагсаалтыг янз бүрийн категоритой өөр хуудсанд хэвлэхийг хүсвэл цааш нь уншина уу. Дараахь зүйл дээр бид танд үүнийг олж авах 2 аргыг танилцуулах болно.

Арга 1: Ажлын жагсаалтыг гараар нэг нэгээр нь хэвлэх

1. Эхлээд Outlook дээрээс "Tasks" панел руу хандана уу.
2. Дараа нь Task хавтас нээнэ үү.
3. Дараа нь "Хайлт" туузыг идэвхжүүлэхийн тулд "Ctrl + E" товчийг дарна уу.
4. Үүний дараа "Хайлт" таб дээр "Ангилах" товчийг дарна уу.
5. Унтраах жагсаалтаас өнгөний ангиллыг сонгоно уу.
6. Дараа нь жагсаалтад зөвхөн сонгосон ангилалтай даалгаварууд үлдэх болно.
7. Одоо энэ даалгаврын жагсаалтыг хэвлэхийн тулд "Файл"> "Хэвлэх" руу орно уу.
8. Дараа нь ижил аргаар бусад өнгөт ангиллын даалгаврын жагсаалтыг нэг нэгээр нь хэвлэ.

Арга 2: VBA-ээр ажлын жагсаалтыг багцаар хэвлэ

1. Хамгийн эхэнд VBA редакторыг “Таны Outlook дээр VBA кодыг хэрхэн ажиллуулах вэ".
2. Дараа нь "MS Excel объектын сан"-д дараах байдлаар лавлагаа нэмнэ үү.VBA дээр объектын номын сангийн лавлагааг хэрхэн нэмэх вэ".
3. Дараа нь дараахь VBA кодыг модульд хуулж ав.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Үүний дараа “F5” товчлуур дээр дарж энэ макро даруй ажиллуулна уу.
5. Макро дуусах үед янз бүрийн категорийн даалгаврын жагсаалтыг дараахь дэлгэцийн агшинд харуулсны дагуу өөр хуудсанд хэвлэнэ.

Аюулгүй болгосон PST файлаас үнэ цэнэтэй өгөгдлийг буцааж авах

Хэрэв танд нэвтрэх боломжгүй PST файл байгаа бол таны дараагийн алхам эргэлзээгүй болно PST засвар. Энэ тохиолдолд та эхлээд ирсэн мэйлийг засах хэрэгслийг туршиж үзэх боломжтой. Энэ нь бүтэлгүйтсэн тохиолдолд та өөр гадаад хэрэгслийг туршиж үзэх боломжтой DataNumen Outlook Repair. Энэ нь PST өгөгдлийг хурдан хугацаанд сэргээх боломжтой юм.

Зохиогчийн танилцуулга:

Ширли Жан бол мэдээлэл сэргээх мэргэжилтэн юм DataNumen, Үүнд мэдээлэл сэргээх технологиор дэлхийд тэргүүлэгч, Inc. mdf-ийг сэргээх програм хангамжийн бүтээгдэхүүнийг засах хэтийн төлөв. Дэлгэрэнгүй мэдээллийг авна уу WWW.datanumen.com