Outlook VBA를 사용하여 모든 메일 폴더에서 특정 규칙을 빠르게 실행하는 방법

Outlook 솔루션 2025 년 9 월 29 일

기본적으로 한 번에 하나의 폴더에서만 규칙을 실행할 수 있습니다. 이 기사에서는 VBA 코드를 사용하여 모든 메일 폴더에서 특정 규칙을 실행하는 방법을 설명합니다.

Outlook에서는 사용자가 규칙을 수동으로 실행할 수 있습니다. "규칙 및 경고"대화 상자에 액세스하여 "지금 규칙 실행"버튼을 누르기 만하면됩니다. 후속 대화 상자에서 특정 규칙을 선택하고이 규칙을 실행할 폴더를 선택합니다. 그러나 모든 메일 폴더에서 규칙을 빠르게 실행하려면 다음 VBA 코드를 사용할 수 있습니다.

모든 메일 폴더에서 특정 규칙을 빠르게 실행

먼저 Outlook 프로그램을 실행하세요.
그런 다음 기본 Outlook 창에서 "Alt + F11"키 버튼을 누릅니다.
다음으로 나타나는 "Microsoft Visual Basic for Applications"창에서 사용하지 않는 모듈을 열어야합니다.
그런 다음 아래의 VBA 코드를이 모듈 창에 복사합니다. 또한 규칙 이름과 같이 대소 문자에 따라 일부 줄을 변경해야합니다.

Sub RunSpecificRule_AllMailFolders()
    Dim objStores As Outlook.Stores
    Dim objStore As Outlook.Store
    Dim objPSTFile As Outlook.Folder
    Dim objFolders As Outlook.folders
    Dim objFolder As Object

    Set objStores = Outlook.Application.Session.Stores
 
    'Process all Outlook PST files in your Outlook
    For Each objStore In objStores
        Set objPSTFile = objStore.GetRootFolder
        For Each objFolder In objPSTFile.folders
            Call ProcessFolders(objFolder)
        Next
    Next

    MsgBox "Complete!", vbExclamation + vbOKOnly, "Run Rule "
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objRules As Outlook.Rules
    Dim objRule As Outlook.Rule
    Dim objSubfolder As Outlook.Folder

    Set objRules = Outlook.Application.Session.DefaultStore.GetRules
    'Change the rule name as per your actual case
    Set objRule = objRules.Item("Move Mails to Temp")
 
    On Error Resume Next
    'Only work on non-empty Mail folder
    If objCurrentFolder.Items.count > 0 And objCurrentFolder.DefaultItemType = olMailItem Then
       With objRule
            .Enabled = True
            .Execute ShowProgress:=True, Folder:=objCurrentFolder, IncludeSubfolders:=True
       End With
    End If
 
    'Process subfolders recursively
    If objCurrentFolder.folders.count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

그런 다음 Outlook 매크로 설정을 확인하여 매크로가 허용되는지 확인해야합니다.
결국 시도해 볼 수 있습니다.

"RunSpecificRule_AllMailFolders"서브 루틴을 클릭하기 만하면됩니다.
그런 다음 F5 키 버튼을 눌러이 코드를 트리거합니다.
다음으로 매크로가 즉시 실행됩니다.
완료되면 다음 스크린 샷과 같은 메시지가 표시됩니다. 규칙이 완료되었음을 나타냅니다.

악성 매크로주의

우리 모두 알다시피 악성 이메일은 점점 더 만연해졌습니다. 이러한 이메일에는 종종 악성 매크로가 포함됩니다. 따라서 Outlook 매크로 보안 수준을 낮게 설정하면 숨겨진 바이러스 및 맬웨어에주의해야합니다. 또한 다음과 같은 강력한 PST 수정 도구를 확보하는 것이 현명합니다. DataNumen Outlook Repair. 할 수있다 PST 수리 땀을 흘리지 않고 파일을 작성하고 최대 데이터를 추출하십시오.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. mdf 복구 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM