각 색상 범주의 Outlook 약속에 소요 된 총 시간을 빠르게 내보내는 방법

Outlook 솔루션 2025 년 9 월 29 일

각 색상 범주의 약속에 소비한 총 시간에 대한 보고서를 생성하려면 이 기사에서 소개한 방법을 활용할 수 있습니다. 수동으로 계산할 필요 없이 빠른 시간 내에 이 작업을 수행하는 데 도움이 될 수 있습니다.

많은 사용자가 로그인에 익숙합니다.ost Outlook 일정에서 자신의 활동. 또한 보다 쉽게 관리하고 구분할 수 있도록 각각에 카테고리를 지정합니다. 이 경우 일부 사용자는 각 색상 범주의 일정 항목에 소요된 총 시간을 보여주는 보고서를 생성하려고 합니다. 의심의 여지없이 수동으로 계산하고 입력하는 것은 번거로운 일입니다. 따라서 여기에서는 간단한 클릭을 통해 이 작업을 수행할 수 있는 방법을 공유합니다.

각 색상 범주의 약속에 소요된 총 시간 내보내기

먼저 Outlook 응용 프로그램을 시작하십시오.
그런 다음 Outlook 창에 들어간 후 "Alt + F11" 키 버튼을 누를 수 있습니다.
그러면 "Microsoft Visual Basic for Applications"창에 액세스 할 수 있습니다.
다음으로 "Microsoft Excel Object Lib"를 활성화해야 합니다.rar와이". "도구" > "참조"를 클릭하여 달성할 수 있습니다.
그런 다음 사용하지 않는 모듈을 찾아서 열어야 합니다.
그런 다음 다음 VBA 코드를 이 모듈에 복사해야 합니다.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

마지막으로 도구 모음에서 "실행" 아이콘을 클릭하거나 "F5" 키 버튼을 눌러도 이 매크로를 트리거할 수 있습니다.
그런 다음 특정 캘린더를 선택하라는 메시지가 표시됩니다.
"확인"을 선택하고 누르면 매크로가 계속 실행됩니다. 작업이 완료되면 배경에 새 Excel 파일이 표시됩니다.
액세스할 수 있습니다. 다음 스크린샷과 같이 표시됩니다.

Outlook 주변의 잠재적인 위협을 주시하십시오.

Outlook 사용자는 알 수 없는 전자 메일 첨부 파일, 포함된 링크 및 사람의 실수를 포함하여 모든 잠재적 위험을 주의해야 합니다. 그렇지 않으면 Outlook이 언제든지 손상될 수 있습니다. 또한 정기적으로 Outlook 데이터를 백업하고 전문 복구 도구를 유지하는 것이 필요합니다. DataNumen Outlook Repair m 중 하나입니다ost 적극 권장되는 수정 도구입니다. 할 수 있습니다 수리 Outlook 순식간에 문제.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 손상된 mdf 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM