각 Outlook 폴더의 총 항목 수를 Excel로 빠르게 내보내는 방법

Outlook 솔루션 2025 년 9 월 29 일

각 Outlook 폴더의 항목 수에 대한 보고서를 얻으려면이 문서에 소개 된 방법을 사용할 수 있습니다. 신속하게 계산을 수행하고 결과를 Excel 파일로 내 보냅니다.

이전 기사에서 –“Outlook VBA를 통해 폴더 및 모든 하위 폴더의 총 항목 수를 빠르게 가져 오는 방법”, VBA를 사용하여 폴더의 항목 수를 가져 오는 방법을 배울 수 있습니다. 그러나 즉, 모든 폴더의 항목을 계산하려면 각 폴더를 선택하고 매크로를 하나씩 실행해야합니다. 약간 지루합니다. 따라서 카운트를 Excel 파일로 내보내는 다른 방법을 알려드립니다.

각 Outlook 폴더의 총 항목 수를 Excel로 내보내기

처음에 Outlook 프로그램을 시작하십시오.
그런 다음 기본 Outlook 창에서 "Alt + F11"키 버튼을 누릅니다.
다음으로 사용하지 않는 모듈을 열어야하는 "Microsoft Visual Basic for Applications"창으로 이동합니다.
그런 다음 다음 VBA 코드를 복사하여이 모듈에 붙여 넣습니다.

Public strExcelFile As String
Public objExcelApp As Excel.Application
Public objExcelWorkbook As Excel.Workbook
Public objExcelWorksheet As Excel.Worksheet

Sub Export_CountOfItems_InEachFolder_toExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Create a new Excel file
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Count Items"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Items Count (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderItemCount As Long
    Dim nLastRow As Integer
 
    lCurrentFolderItemCount = objCurrentFolder.Items.Count
 
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nLastRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nLastRow) = lCurrentFolderItemCount
 
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

그런 다음 Outlook 매크로 보안 수준을 낮음으로 변경해야합니다.
그런 다음 새로 추가 된 매크로로 돌아가서 F5 키 버튼을 눌러이 매크로를 실행할 수 있습니다.
다음으로 소스 PST 파일을 선택하고 "확인"을 눌러야합니다.
매크로가 완료되면 미리 정의 된 로컬 폴더로 이동하여 다음 스크린 샷과 같은 새 Excel 파일을 찾을 수 있습니다.

성가신 PST 오류 해결

Outlook을 사용하는 동안 다양한 문제가 발생했을 수 있습니다. 사소한 문제를 처리하기 위해 간단히 받은 편지함 수리 도구. 그럼에도 불구하고 문제가 너무 심각해서 내장 도구가 할 수있는 것 이상이라면, 다음과 같은 더 강력한 도구를 사용해야합니다. DataNumen Outlook Repair.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. mdf 수리 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM