VBA를 통해 한 Outlook PST 파일에서 다른 파일로 폴더 구조를 빠르게 복사하는 방법

Outlook 솔루션 2025 년 9 월 29 일

한 Outlook PST 파일에서 다른 파일로 폴더 구조를 복사하려면이 문서에서 소개 한 방법을 사용하면 VBA를 사용하여 한 번에 파일을 가져 오는 방법을 알려줍니다.

이메일을 더 잘 관리하기 위해 기본 Outlook 파일에 여러 사용자 지정 폴더를 만들었을 수 있습니다. 따라서 새 Outlook PST 파일을 만들 때 동일한 폴더 구조를 적용 할 수 있습니다. 사실, 이전 기사에서 –“현재 폴더를 유지하는 2 단계rar새 Outlook 파일에서 chy”,“아카이브”기능을 사용하여이를 달성하는 전통적인 방법을 배울 수 있습니다. 그럼에도 불구하고 실제로는 여전히 약간 지루합니다. 그것과 비교할 때 VBA 코드를 사용하면 훨씬 더 빨리 얻을 수 있습니다. 따라서 다음에서는 정교한 단계와 코드를 알려 드리겠습니다.

한 Outlook PST 파일에서 다른 파일로 폴더 구조 복사

처음에는 start Outlook 프로그램.
그런 다음 Outlook 창에서 "Alt + F11"키 버튼을 누릅니다.
다음으로 Outlook VBA 편집기 창으로 들어갑니다.
그런 다음 다음 VBA 코드를 복사하여 새 모듈에 붙여 넣습니다.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

그런 다음 매크로 보안 수준을 낮음으로 변경하십시오.
나중에 VBA 편집기 창으로 돌아가서 "F5"키 버튼을 눌러 매크로를 실행합니다.
마지막으로 매크로가 작동을 마치면 "Completed!"라는 메시지가 표시됩니다.
이 시점에서 메일 탐색 창으로 이동할 수 있습니다. 아래 이미지와 같이 원본 PST 파일과 동일한 폴더 구조에있는 새 Outlook 데이터 파일이 표시됩니다.

불쾌한 PST 문제에 대처

Outlook PST는 오류가 발생하기 쉬우므로 많은 사람들이 Outlook에서 다양한 문제가 발생했을 것입니다. 그들에 직면하면 먼저 Outlook받은 편지함 복구 도구를 사용하여 시도해 볼 수 있습니다. 실패하면 다음과 같은 더 강력한 타사 도구를 적용 할 수 있습니다. DataNumen Outlook Repair, 이는 수 Outlook 수정 바람과 같은 PST 오류.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL Server 고정 된 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM