Outlook 전자 메일에 Word 문서의 특정 페이지를 빠르게 첨부하는 방법

Outlook 솔루션 2025 년 9 월 29 일

MS Word에는 사용자가 현재 Word 문서를 전자 메일 첨부 파일로 보낼 수 있도록 지원하는 직접적인 기능이 있습니다. 그러나 때로는 Outlook 전자 메일에 Word 문서의 특정 페이지만 첨부하기를 원할 수도 있습니다. 이제 이 기사에서 방법을 공유합니다.

MS Word 응용 프로그램에서 전체 Word 문서를 전자 메일 첨부 파일로 보내려면 "파일" 메뉴로 이동하여 "저장 및 보내기" 탭으로 이동하면 됩니다. 그 아래에 "첨부 파일로 보내기" 버튼이 있습니다. 그러나 때때로 보내려는 내용은 문서의 특정 페이지일 수 있습니다. 이 상황에서 다음에서 소개하는 방법을 사용하여 이를 달성할 수 있습니다.

전자 메일에 Word 문서의 특정 페이지 첨부

먼저 이메일로 보내려는 특정 페이지가 있는 소스 Word 문서를 열어야 합니다.
그런 다음 MS Word 창에 들어간 후 “Alt + F11” 키 버튼을 눌러야 합니다.
다음으로 MS Word에서 VBA 편집기에 액세스할 수 있습니다.
그런 다음 "Microsoft Outlook Object Lib"를 활성화해야 합니다.rar와이". "도구" > "참조"를 눌러 달성할 수 있습니다.
그런 다음 다음 VBA 코드를 사용하지 않는 모듈에 복사해야 합니다.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

마지막으로 이 매크로를 실행할 수 있습니다. F5 키 버튼을 누르거나 도구 모음에서 "실행" 아이콘을 누르기만 하면 됩니다.
매크로가 완료되면 다음 스크린샷과 같이 원본 Word 문서의 발췌 부분이 첨부된 새 Outlook 전자 메일이 표시됩니다.

손상된 Outlook 파일에서 최대 데이터 추출

수십 년 동안 Outlook을 사용했다면 팝업 내부 오류 메시지, 갑작스러운 충돌 및 심각한 파일 손상을 비롯한 다양한 Outlook 문제에 직면했을 수 있습니다. 사실 때문에 스캔프스트, 내장 수리 도구는 작은 문제만 처리할 수 있으므로 외부의 강력한 수정 도구를 편리하게 유지하는 것이 좋습니다. DataNumen Outlook Repair. 손상된 Outlook 데이터 파일에서 최대 데이터를 끌어낼 수 있습니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL 수정 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM