Windows 폴더의 마지막 수정 파일을 Outlook 이메일에 빠르게 첨부하는 방법

Outlook 솔루션 2025 년 9 월 29 일

경우에 따라 특정 Windows 폴더에서 마지막으로 수정된 파일을 빠르게 찾아 Outlook 전자 메일에 첨부해야 할 수 있습니다. 이 경우 이 기사에서 소개한 방법을 활용할 수 있습니다.

일부 사용자는 Outlook이 Windows 폴더에서 마지막으로 수정된 파일을 신속하게 찾아 전자 메일에 추가하기를 원합니다.ost 최근에 생성, 변경 또는 저장된 파일. 그러나 Outlook은 이러한 직접적인 기본 기능을 제공하지 않습니다. 따라서 다음에서는 쉽게 구현할 수 있는 VBA 코드를 공개합니다.

Windows 폴더의 마지막 수정 파일을 이메일에 첨부

처음에는 Outlook 응용 프로그램을 시작해야합니다.
그런 다음 기본 Outlook 창으로 들어간 후 "Alt + F11" 키 버튼을 누를 수 있습니다.
다음으로 성공적으로 Outlook VBA 편집기 창에 액세스합니다.
그런 다음 사용하지 않는 모듈을 찾아서 열어야 합니다.
그런 다음 이 모듈 창에 다음 VBA 코드를 복사하여 붙여넣습니다.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

그런 다음 현재 VBA 편집기 창을 종료하고 빠른 실행 도구 모음이나 메시지 창의 리본에 새 매크로를 추가할 수 있습니다.
나중에 Outlook 매크로 보안 수준을 낮음으로 변경해야합니다.
결국 시도해 볼 수 있습니다.

먼저 평소와 같이 새 Outlook 전자 메일을 만들고 작성합니다.
그런 다음 아래 이미지와 같이 빠른 실행 도구 모음에서 매크로 버튼을 누르십시오.
다음으로 소스 Windows 폴더를 선택하고 "확인"을 눌러야 합니다.
선택한 Windows 폴더에 이러한 파일이 있으면 다음 스크린샷과 같은 프롬프트가 표시됩니다.
"예"를 누르면 이 파일이 한 번에 첨부됩니다.

가능한 한 빨리 Outlook 문제 해결

Outlook 문제가 발생할 때마다 가능한 한 빨리 문제를 해결하는 것이 좋습니다. 이 상황에서는 강력한 준비를하는 것이 좋습니다. Outlook 수정 사전에 도구와 같은 DataNumen Outlook Repair. PST 오류를 수정하고 Outlook 데이터를 효과적으로 복구할 수 있습니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 손상된 mdf 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM