여러 Outlook 메시지 (.msg) 파일에서 모든받는 사람을 빠르게 추출하는 방법

Outlook 솔루션 2025 년 9 월 29 일

일부 사용자는 Outlook 이메일에서 저장된 여러 Outlook 메시지 파일에서 모든 수신자를 빠르게 추출하려고합니다. 자,이 post 빠른 접근 방식을 공유하기 위해 이것을 살펴볼 것입니다.

단일 Outlook 메시지 파일에서 수신자를 추출하려면 두 번 클릭하여 연 다음 열린 메시지 창에서 수신자를 복사하면 됩니다. 그러나 Outlook 메시지 파일의 배치를 처리해야 하는 경우 수동 방법은 충분히 효율적이지 않습니다. 따라서 훨씬 더 효율적인 방법을 찾을 수 있습니다. 여기에서 우리는 당신에게 그러한 것을 소개 할 것입니다. 자세한 내용을 보려면 계속 읽으십시오.

여러 Outlook 메시지(.msg) 파일에서 모든 받는 사람 추출

로tart, "에 따라 Outlook VBA 편집기에 액세스하십시오.Outlook에서 VBA 코드를 실행하는 방법".
그런 다음 다음 VBA 코드를 복사하여 빈 모듈에 붙여넣습니다.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

그런 다음 첫 번째 서브루틴에서 커서를 이동합니다.
그런 다음 "실행" 버튼을 클릭하거나 "F5" 키를 누릅니다.
그런 다음 팝업 대화 상자에서 원본 Outlook 메시지(.msg) 파일이 포함된 Windows 폴더를 선택합니다.
선택 후 "확인"을 클릭하면 매크로가 계속 실행됩니다.
매크로가 완료되면 다음 스크린샷과 같이 추출된 모든 수신자의 이메일 주소를 나열하는 메시지가 표시됩니다.

위험으로부터 Outlook 데이터 보호

Outlook 데이터는 확실히 손상되기 쉽습니다. 따라서 Outlook 데이터를 보호하는 것은 매우 번거로운 작업입니다. Outlook 데이터를 정기적으로 백업하는 데 인내가 필요합니다. 또한, 가능하면 경험 있고 전문적인 Outlook을 준비하는 것이 현명하고 권장됩니다. PST 수리 도구, 같은 DataNumen Outlook Repair, Outlook이 손상된 경우 즉각적이고 시기 적절한 구조를 얻을 수 있습니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 복구 Sql Server 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM