특정 직함을 가진 모든 Outlook 연락처에서 연락처 그룹을 빠르게 만드는 방법

Outlook 솔루션 2025 년 9 월 29 일

특정 직책을 가진 연락처와보다 쉽게 통신하기 위해 이러한 연락처에서 연락처 그룹을 빠르게 만들 수 있습니다. 이제이 기사에서는 빠른 방법을 공유 할 것입니다.

특정 직함을 가진 연락처에 이메일, 작업 또는 회의 초대를 자주 일괄 전송하는 경우 연락처 그룹을 만들면 훨씬 편리합니다. 일반적으로 표준 방식에서는 먼저 새 연락처 그룹을 만든 다음 그룹에 연락처를 하나씩 구성원으로 추가해야합니다. 조금 번거 롭습니다. 따라서 다음에서 우리는 그것을 얻는 훨씬 더 빠른 방법을 알려줄 것입니다.

특정 직책을 가진 모든 연락처에서 연락처 그룹 만들기

먼저 연락처 폴더에서 특정 직책이있는 연락처를 선택합니다.
그런 다음 "Alt + F11"을 눌러 Outlook VBA 편집기에 액세스합니다.
다음으로 다음 VBA 코드를 빈 모듈 또는 프로젝트에 복사합니다.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

그 후 커서를 첫 번째 서브 루틴으로 이동합니다.
마지막으로 "F5"키 버튼을 눌러이 매크로를 실행합니다.
매크로가 완료되면 새 연락처 그룹이 표시됩니다. 여기에는 1 단계에서 선택한 연락처의 직함이 동일한 모든 연락처가 포함됩니다.

Outlook 데이터를 효과적으로 보호

Outlook은 기능이 풍부하지만 취약하다는 사실을 없앨 수는 없습니다. 따라서 소중한 Outlook 데이터를 잃지 않으려면 데이터를 보호하기 위해 노력해야합니다. 예를 들어 정기적으로 Outlook 데이터를 백업해야합니다. 또한 저렴한 경우 다음과 같은 최첨단 PST 복구 도구를 사용하는 것이 좋습니다. DataNumen Outlook Repair, 이는 수 PST 수리 jiff의 데이터.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 손상된 SQL 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM