제목없이 Outlook 전자 메일을 보내기 전에 본문의 첫 줄을 제목으로 자동 지정하는 방법

Outlook 솔루션 2025 년 9 월 29 일

일부 사용자는 제목이없는 전자 메일을 보낼 때 Outlook에서 전자 메일 본문의 첫 번째 줄을 제목으로 자동 사용하기를 원합니다. 이제이 기사에서는 VBA 코드를 통해 구현하는 방법을 소개합니다.

여러 사용자가 이메일을 작성하고 보낼 때 제목 입력을 잊어 버리는 경우가 많습니다. 따라서 일반적으로 보내는 전자 메일에 제목이없는 경우 Outlook에서 전자 메일 본문의 첫 번째 줄까지 자동으로 제목을 채울 수 있기를 바랍니다. 이하, 쉽고 편리한 방법을 알려 드리겠습니다.

제목없이 이메일을 보내기 전에 자동으로 본문의 첫 줄을 제목으로 지정

처음에는 Outlook 응용 프로그램을 시작하십시오.
그런 다음 "Outlook에서 VBA 코드를 실행하는 방법", VBA 편집기에 들어갈 수 있습니다.
다음으로, VBA 편집기에서 "MS Word 개체 라이브러리"에 대한 참조를 "에 따라 추가합니다."VBA에서 개체 라이브러리 참조를 추가하는 방법".
나중에 아래 코드를 "ThisOutlookSession"프로젝트에 복사하십시오.

Private WithEvents objInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail And Inspector.CurrentItem.Subject = "" Then
       Inspector.CurrentItem.Subject = " "
    End If
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objMailSelection As Word.Selection
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       If Len(Trim(objMail.Subject)) = 0 Then
          If MsgBox("No subject! Whether to take first line as subject?", vbQuestion + vbYesNo) = vbYes Then
             Set objMailDocument = objMail.GetInspector.WordEditor
             Set objMailSelection = objMailDocument.Application.Selection
 
             objMailDocument.Range(0, 0).Select
             objMailSelection.MoveEnd wdLine
 
             'Take first line of body as subject
             objMail.Subject = objMailSelection.Text
          End If
       End If
     End If
End Sub

그 후, 커서를 "Application_Startup" 서브루틴에 놓고 "F5" 키를 누르십시오.
마지막으로 시도해 볼 수 있습니다.

처음에는 제목 만 비어있는 이메일을 작성하고 작성하십시오.
그런 다음 "보내기"버튼을 클릭합니다.
나중에 본문의 첫 줄을 제목으로 사용할 것인지 묻는 메시지가 표시됩니다.
“예”버튼을 선택하면 이메일 본문의 첫 줄이 추출되어 제목으로 사용되며 이메일이 발송됩니다.

Outlook 데이터를 안전하게 유지

물론 Outlook에는 여러 중요한 전자 메일과 기타 항목이 있습니다. 따라서 Outlook 데이터 손실을 원하지 않아야합니다. 그런 다음 Outlook의 정기적 인 데이터 백업을 만들고 내장 된 복구 도구를 사용하여 다음과 같은 몇 가지 작업을 수행해야합니다. Outlook 수정 오류 및 강력한 외부 복구 유틸리티 준비. DataNumen Outlook Repair PST 복구율이 높기 때문에 좋은 선택입니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL 복구 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM