예상 시간 내에 특정 이메일의 회신을받지 못하는 경우 알림을받는 방법

Outlook 솔루션 2025 년 9 월 29 일

이 기사에서는 VBA를 사용하여 특정 시간 내에 특정 전자 메일의 회신을받지 못한 경우 Outlook에서 알림 전자 메일을 보낼지 여부를 자동으로 프롬프트하도록하는 빠른 트릭을 알려줍니다.

때로는 매우 중요한 이메일의 경우 답장을 기다리게 될 것입니다. 즉, 수신자가 가능한 한 빨리 답장 할 수 있기를 바랍니다. 그렇지 않으면 예상 시간 내에 아직 답장을받지 못한 경우 수신자에게 후속 알림 이메일을 다시 보냅니다. 따라서이 요구 사항에 대한 응답으로 VBA를 사용하여 이러한 경우 Outlook에서 자동으로 경고하고 메시지를 표시하도록하는 방법을 소개합니다. 정교한 단계와 코드를 얻으려면 계속 읽으십시오.

예상 시간 내에 특정 이메일의 회신을받지 못하면 알림 받기

가장 먼저 Outlook을 실행하세요.
그런 다음 특정 이메일에 특정 알림 시간을 설정해야합니다.

먼저 특정 이메일을 마우스 오른쪽 버튼으로 클릭하십시오.
그런 다음 "후속 조치"> "알림 추가"를 선택합니다.
대화 상자에서 회신을받을 특정 시간과 동일한 알림 시간을 설정할 수 있습니다.

그런 다음 "Alt + F11"키 버튼을 눌러 Outlook VBA 편집기에 액세스합니다.
다음으로 새 창에서 "ThisOutlookSession"프로젝트를 열고 다음 코드를 복사합니다.

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'If receive the reply, clear the flag and remove the reminder
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objSentItems As Outlook.Items
    Dim objVariant As Variant
    Dim i As Long
    Dim strSubject As String
    Dim dSendTime As String
 
    Set objSentItems = Outlook.Application.Session.GetDefaultFolder(olFolderSentMail).Items
 
    If Item.Class = olMail Then
       For i = 1 To objSentItems.Count
           If objSentItems.Item(i).Class = olMail Then
              Set objVariant = objSentItems.Item(i)
              strSubject = LCase(objVariant.Subject)
              dSendTime = objVariant.SentOn
 
              If LCase(Item.Subject) = "re: " & strSubject Or InStr(LCase(Item.Subject), strSubject) > 0 Then
                 If Item.SentOn > dSendTime Then
                    With objVariant
                         .ClearTaskFlag
                         .ReminderSet = False
                         .Save
                    End With
                 End If
              End If
           End If
       Next i
    End If
End Sub

'Get a prompt asking if to send a notification email
Private Sub Application_Reminder(ByVal Item As Object)
    Dim strPrompt As String
    Dim nResponse As Integer
    Dim objFollowUpMail As Outlook.MailItem
 
    'You can change the subject as per your real case
    If (Item.Class = olMail) And (LCase(Item.Subject) = "datanumen outlook repair") Then
       strPrompt = "You haven't yet recieved the reply of " & Chr(34) & Item.Subject & Chr(34) & " within your expected time. Do you want to send a follow-up notification email?"
       nResponse = MsgBox(strPrompt, vbYesNo + vbQuestion, "Confirm to Send a Follow-Up Notification Email")
       If nResponse = vbYes Then
          Set objFollowUpMail = Application.CreateItem(olMailItem)
          With objFollowUpMail
               .To = Item.Recipients.Item(1).Address
               .Subject = "Follow Up: " & Chr(34) & Item.Subject & Chr(34)
               .Body = "Please respond to my email " & Chr(34) & Item.Subject & Chr(34) & "as soon as possible"
               .attachments.Add Item
               .Display
          End With
       End If
    End If
End Sub

그 후이 코드에 서명하십시오.
나중에 디지털 서명 된 매크로를 허용하도록 Outlook 매크로 설정을 변경합니다.
마지막으로 Outlook을 다시 시작하여 새 매크로를 활성화하십시오. 이제부터 Outlook은 다음과 같이 작동합니다.

미리 알림이 표시되기 전에 특정 전자 메일의 회신을받은 경우 Outlook은 자동으로 플래그를 지우고 미리 알림을 비활성화합니다.
미리 알림이 실행될 때 회신을받지 못한 경우 Outlook에서 후속 알림 전자 메일을 보낼 것인지 묻습니다. “예”를 선택하면 이메일이 발송됩니다. “아니오”를 선택하면 프롬프트가 즉시 사라집니다.

성가신 Outlook 문제 해결

Outlook은 오류가 발생하기 쉬우므로 Outlook 손상,받은 편지함 도구 인 Scanpst.exe에 의존하는 것이 좋습니다. 다음과 같은 다른 강력하고 평판이 좋은 수리 도구를 준비해야합니다. DataNumen Outlook Repair, Scanpst.exe가 해결할 수없는 성가신 문제를 처리 할 수 있습니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL 손상 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM