Outlook에서 여러 iCalendar (.ics) 파일을 일괄 여는 방법

Outlook 솔루션 2025 년 9 월 29 일

로컬 드라이브에 iCalendar (.ics) 파일이 많고 Outlook에서 일괄 적으로 열려면이 문서를 읽을 수 있습니다. 여기에서는 VBA 코드를 활용하여이를 실현하는 방법을 알려드립니다.

일반적으로 Outlook에서 iCalendar (.ics) 파일을 열려면 "가져 오기"기능을 쉽게 사용할 수 있습니다. 그러나 여러 개를 일괄 적으로 열려면 한 번에 하나 이상의 파일을 선택할 수 없기 때문에 "가져 오기"는 무력합니다. 따라서 다른 접근 방식을 사용해야합니다.

이러한 ics 파일이 동일한 로컬 폴더에 저장되어있는 경우 해당 파일을 선택하고 "Enter"키를 눌러 대량으로 열 수 있습니다. 그러나 드라이브 아래의 다른 폴더에 있으면 위의 방법도 쓸모가 없습니다. 이 경우 기본 폴더 아래의 모든 폴더를 재귀 적으로 처리 할 수있는 다음 방법을 사용할 수 있습니다. 이제 자세한 내용을 보려면 계속 읽으십시오.

여러 iCalendar (.ics) 파일 일괄 열기

로tart, Outlook 프로그램을 시작하십시오.
그런 다음 "Alt + F11"을 눌러 VBA 편집기에 액세스합니다.
그런 다음 새 창에서 다음 VBA 코드를 모듈에 입력하십시오.

Sub BatchOpenMultipleICalendarFiles()
    Dim objShell, objWindowsFolder As Object
    Dim strWindowsFolder As String
 
    'Select a Windows Folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"
       Call LoopFolders(strWindowsFolder)
 
       MsgBox "Completed!", vbInformation + vbOKOnly, "Open iCalendar Files"
    End If
End Sub

Sub LoopFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objICalendarFile As Object
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    'Open each iCalendar file
    For Each objFile In objFolder.Files
        If LCase(objFileSystem.GetExtensionName(objFile)) = "ics" Then
           Set objICalendarFile = objFile
           On Error Resume Next
           Application.GetNamespace("MAPI").OpenSharedFolder objICalendarFile.Path
        End If
    Next
 
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
              Call LoopFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

다음으로 커서를“BatchOpenMultipleICalendarFiles”서브 루틴으로 이동합니다.
궁극적으로 "F5"를 눌러이 매크로를 트리거합니다.
그런 다음 팝업 대화 상자에서 iCalendar 파일이 저장된 Windows 폴더 또는 드라이브를 선택합니다.
"완료"메시지를 받으면 Outlook의 "일정"창에 액세스합니다.
다음 스크린 샷과 같이 해당 Windows 폴더의 모든 iCalendar 파일이 거기에 있음을 확인할 수 있습니다.

근처에 강력한 PST 수정 도구 준비

Outlook이 오류 및 손상되기 쉽다는 것을 알고 계실 것입니다. 따라서 정기적으로 Outlook 데이터 파일을 백업하는 것이 좋습니다. 이렇게하면 Outlook 파일이 손상 되더라도 백업에서 중요한 Outlook 데이터를 간단히 가져올 수 있습니다. 그러나 그러한 백업이 없으면 다음과 같은 놀라운 복구 도구를 사용해야합니다. DataNumen Outlook Repair. 그것은 당신을 도울 수 있습니다 Outlook 수정 코르크와 같은 문제.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. mdf 복구 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM