Outlook VBA를 사용하여 여러 연락처의 사진 및 정보를 일괄 내보내는 방법

Outlook 솔루션 2025 년 9 월 29 일

연락처의 사진과 기본 정보를 로컬 디스크의 폴더에 일괄 추출하려면 Outlook VBA를 사용해야합니다. 이 기사에서는이를 달성하는 방법을 자세히 설명합니다.

Outlook에서는 "가져 오기 및 내보내기"기능을 통해 연락처 정보를 내보낼 수 있습니다. "파일"> "인쇄"> "가져 오기"> "파일로 내보내기"로 이동할 수 있습니다.

그러나이 기능을 사용하면 연락처 사진을 내보낼 수 없습니다. 따라서 연락처 정보와 사진을 모두 추출하려면 Outlook VBA로 되돌려 야합니다. 다음은 연락처 사진을 지정된 로컬 폴더에 저장하고 연락처 정보를 텍스트 파일로 추출 할 수있는 VBA 코드 및 단계입니다.

여러 연락처의 사진 및 정보 일괄 내보내기

우선 Outlook을 시작하고 "Alt + F11"키 버튼을 누릅니다.
그런 다음 VBA 편집기에 액세스 할 수 있습니다. 이제 사용하지 않는 모듈을 열거 나 "삽입"> "모듈"을 통해 새 모듈을 만들어야합니다.
그런 다음 다음 VBA 코드를 복사하여 새 모듈에 붙여 넣습니다.

Sub BatchExportContactPhotosandInformation()
    Dim objContacts As Outlook.Items
    Dim objContact As ContactItem
    Dim strContactInfo As String
    Dim objFileSystem As Object
    Dim objTextfile As Object
    Dim objAttachments As Attachments
    Dim objAttachment As Attachment
    Dim strName As String
 
    'Specify the contacts in the default contact folder
    Set objContacts = Outlook.Application.Session.GetDefaultFolder(olFolderContacts).Items
 
    For Each objContact In objContacts
        If TypeOf objContact Is ContactItem Then
           'Get the contact's primary informtaion
           strContactInfo = "Name: " & objContact.FullName & vbCrLf & "Email: " & objContact.Email1Address & vbCrLf & "Company: " & objContact.Companies & vbCrLf & "Job Title: " & objContact.JobTitle & vbCrLf & "Business Address: " & objContact.BusinessAddress & vbCrLf & "Business Phone: " & objContact.BusinessTelephoneNumber
           'Create a Text file
           Set objFileSystem = CreateObject("Scripting.FileSystemObject")
           'You can change the folder path as per your needs
           Set objTextfile = objFileSystem.CreateTextFile("C:\Outlook Contacts\" & objContact.FullName & ".txt", True)
           objTextfile.WriteLine (strContactInfo)
 
           'Save the contact photos
           If objContact.Attachments.Count > 0 Then
              Set objAttachments = objContact.Attachments
              For Each objAttachment In objAttachments
                  If InStr(LCase(objAttachment.filename), "contactpicture.jpg") > 0 Then
                     strName = objContact.FullName & ".jpg"
                     objAttachment.SaveAsFile ("C:\Outlook Contacts\" & strName)
                  End If
              Next
           End If
       End If
    Next
End Sub

참고 : 위의 코드는 기본 연락처 폴더에있는 연락처의 사진과 정보를 내 보냅니다. 지정된 연락처를 변경할 수 있습니다.

현재 열려있는 폴더에있는 연락처의 사진과 정보를 내보내려면 "Set objContacts =… .."를 다음으로 바꿔야합니다.

Set objContacts = Outlook.Application.ActiveExplorer.CurrentFolder.Items

선택한 연락처의 사진과 정보 만 내보내려면 다음 줄을 사용할 수 있습니다.

Dim objSelection as Selection
Set objSelection = Outlook.Application.ActiveExplorer.Selection
For each objContact in objSelection

그런 다음 VBA 편집기를 닫고 평소와 같이 빠른 액세스 도구 모음에 새 프로젝트를 계속 추가 할 수 있습니다.
마지막으로 빠른 실행 도구 모음에서 매크로 버튼을 클릭 할 수 있습니다. 한 번에 연락처 사진과 정보가 로컬 디스크의 지정된 폴더로 내보내집니다.

다음 스크린 샷과 같이 기본 정보가 나열되는 하나의 텍스트 파일을 열 수 있습니다.

예기치 않은 Outlook 손상 처리

Outlook이 취약하다는 것은 의심 할 여지가없는 사실입니다. 따라서 Outlook이 손상되면 먼저해야 할 일은 진정하는 것입니다. 그런 다음 계속 수리 할 수 있습니다. 손상된 Outlook PST 이메일. 받은 편지함 복구 도구를 사용하여 사용해 볼 수 있습니다. 실패하면 다음과 같은 훨씬 더 강력한 도구를 사용할 수밖에 없습니다. DataNumen Outlook Repair.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 손상된 SQL mdf 데이터베이스 복구 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM