특정 날짜 범위에 예약 된 모든 Outlook 모임을 일괄 취소하는 방법

Outlook 솔루션 2025 년 9 월 29 일

Outlook에서 특정 날짜 범위에 예약 된 모든 회의를 취소하려는 경우이 문서에 소개 된 방법을 사용할 수 있습니다. 이러한 회의를 수동으로 검색하고 취소하지 않아도됩니다.

어떤 이유로 특정 미래 날짜 범위에 개최 될 회의를 조직하거나 참여할 수없는 경우 이러한 모든 회의를 취소 할 수 있습니다. 일반적으로 먼저 알아 낸 다음 하나씩 취소해야합니다. 꽤 귀찮을 것입니다. 따라서 다음에서 우리는 훨씬 더 편리한 다른 방법으로 여러분을 공유 할 것입니다.

특정 날짜 범위에 예약 된 모든 회의 일괄 취소

우선, Outlook 프로그램을 실행하세요.
그런 다음 Outlook에서 "Alt + F11"키 버튼을 눌러야합니다.
다음으로 "Microsoft Visual Basic for Applications"창으로 이동합니다.
이 창에서 사용하지 않는 모듈을 열거 나 새 모듈을 삽입해야합니다.
이후에 다음 VBA 코드를이 모듈에 복사 할 수 있습니다.

Sub BatchCancelAllMeetingsInSpecificDateRange()
    Dim dStartDate As Date
    Dim dEndDate As Date
    Dim objCalendarFolder As Outlook.folder
    Dim objItems As Outlook.Items
    Dim objItemsInDateRange As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim objResponse As Outlook.MeetingItem
 
    'Specify the start date and end date
    dStartDate = InputBox("Enter the start date:", , "10/1/2017")
    dEndDate = InputBox("Enter the end date:", , "10/8/2017")
 
    If dStartDate <> #1/1/4501# And dEndDate <> #1/1/4501# Then
       'Select a calendar folder
       Set objCalendarFolder = Outlook.Application.Session.PickFolder
       Set objItems = objCalendarFolder.Items
       objItems.IncludeRecurrences = True
       objItems.Sort "[Start]"
 
       'Get the appointments in the specific date range
       strFilter = "[Start] >= " & Chr(34) & dStartDate & " 00:00 AM" & Chr(34) & " AND [End] <= " & Chr(34) & dEndDate & " 11:59 PM" & Chr(34)
       Set objItemsInDateRange = objItems.Restrict(strFilter)
 
       objItemsInDateRange.Sort "[Start]"
       For Each objAppointment In objItemsInDateRange
           'Cancel the meetings in this date range
           If objAppointment.MeetingStatus = olMeeting Then
              If objAppointment.Organizer = Outlook.Session.CurrentUser Then
                 objAppointment.MeetingStatus = olMeetingCanceled
                 objAppointment.Save
                 objAppointment.Send
                 objAppointment.Delete
              Else
                 Set objResponse = objAppointment.Respond(olMeetingDeclined)
                 objResponse.Send
                 objAppointment.Delete
              End If
            End If
       Next
    End If
End Sub

결국이 매크로를 지금 바로 실행할 수 있습니다.

현재 매크로 창에서 "F5"키 버튼을 누릅니다.
다음으로 날짜 범위를 지정해야합니다.
그 후, 소스 캘린더 폴더를 선택하고 "확인"을 클릭하라는 다른 대화 상자가 표시됩니다.
마지막으로 매크로가 완료되면 특정 날짜 범위의 모든 회의가 취소되었음을 확인할 수 있습니다.
"보낸 항목"폴더에서 아래 스크린 샷과 같이 회의 취소를 찾을 수 있습니다.

Outlook 오류 수정

수십 년 동안 Outlook을 사용한 경우 몇 가지 오류가 발생했을 것입니다. 다행히 Outlook에는 내장 복구 도구 인 Scanpst가 포함되어 있습니다. 당신은 그것을 사용할 수 있습니다 Outlook 수정 오류. 그러나 실패하면 마지막 수단은 다음과 같은 외부 수정 도구입니다. DataNumen Outlook Repair이 프로그램은 Outlook 파일을 스캔하여 대부분의 오류를 수정하고, 손상된 Outlook 데이터까지 손쉽게 복구할 수 있습니다.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL 수정 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM