Outlook에서 전자 메일에 플래그가 지정된 경우 새 약속을 자동으로 만드는 방법

Outlook 솔루션 2025 년 9 월 29 일

어떤 사람들은 이메일에 플래그를 지정할 때 자동으로 또는 빠르게 새 Outlook 약속을 만들고 싶어합니다. 이 기사에서는 Outlook VBA로이를 실현하는 방법을 소개합니다.

때로는 약속이나 회의를 언급하는 이메일을받을 수 있습니다. 그러나 이것은 Outlook의 일반적인 모임 항목이 아닌 전자 메일입니다. 이 경우 Outlook 일정에서 수동으로 새 약속을 만들어야합니다. 그것은 약간 귀찮습니다. 따라서 Outlook이 자동으로 새 약속을 만들 수 있기를 바랍니다. 그럼에도 불구하고 Outlook에는 전자 메일에 플래그를 지정할 때 자동으로 새 약속을 만드는 기본 지원이 없습니다. 따라서 그것을 달성하기 위해 Outlook VBA를 사용하기로 결정했습니다. 자세한 VBA 코드 및 단계는 다음과 같습니다.

이메일에 플래그가 지정되면 새 약속 자동 생성

먼저 "개발자"탭으로 전환하고 "코드"그룹에서 "Visual Basic"버튼을 누릅니다.
그런 다음 새 "Microsoft Visual Basic for Applications"창에서 "ThisOutlookSession"을 두 번 클릭하여이 프로젝트를 열어야합니다.
그리고 다음 VBA 코드를 복사하여 붙여 넣으십시오.

Public WithEvents olItems As Outlook.Items

Private Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub olItems_ItemChange(ByVal Item As Object)
    Dim oAppt As AppointmentItem
    Dim strMsg As String
    Dim nRes As Integer
 
    On Error Resume Next
 
    If TypeName(Item) = "MailItem" And Item.IsMarkedAsTask = True Then
       strMsg = "Do you want to create a new appointment"
       nRes = MsgBox(strMsg, vbYesNo + vbQuestion, "Confirm Creating Appointment")
       If nRes = vbYes Then
          Set oAppt = Application.CreateItem(olAppointmentItem)
          With oAppt
               .Subject = "New Appt: " & Item.Subject
               .Location = InputBox("Enter the Location, please.")
               'Type the concrete time, such as "12/29/2015 15:30"
               .Start = InputBox("Enter a specific time (format: MM/DD/YYYY hh:mm), please.")
               .Duration = 120
               .Body = "New Appointment: " & vbCrLf & vbCrLf & Item.Body
               .Attachments.Add Item
               .ReminderSet = True
               .ReminderMinutesBeforeStart = 30
               'Use ".Save" to directly save the new appointment
               .Display
          End With
       End If
 
      'To clear the flag on the email
      'If you want to keep email flagged, remove the following 4 lines
       With Item
            .ClearTaskFlag
            .Save
       End With
    End If
End Sub

그런 다음 "VBA 프로젝트 용 디지털 인증서"를 사용하여 새 인증서를 만들고 현재 "ThisOutlookSession"프로젝트에 서명해야합니다.
그런 다음 "Visual Basic"창을 종료하고 디지털 서명 된 매크로 만 허용하도록 매크로 설정을 변경할 수 있습니다.
결국 시도해 볼 수 있습니다.

첫째, 이메일에 대해 프레젠테이션을하고 "신고"아이콘을 클릭합니다. 다음 스크린 샷과 같은 메시지가 표시됩니다.
"예"를 선택한 후 위치를 지정하고 "확인"버튼을 눌러야합니다.
그런 다음 약속 시간을 지정해야합니다.
마지막으로 "확인"을 클릭하면 아래 이미지와 같이 새 약속이 열립니다.

배송 시 요청 사항:

이 VBA 코드에서 미리 알림은 기본적으로 30 분으로 설정됩니다. 코드에서 마음대로 변경할 수 있습니다.
이 코드는 약속 시간을 120 분, 즉 2 시간으로 설정합니다. 필요에 따라 ".Duration = 120"줄을 변경할 수 있습니다.
구체적인 시간을 지정하지 않은 경우 새 약속은 기본적으로 현재 날짜와 시간으로 설정됩니다.
".Save"줄을 추가하여 약속을 직접 저장할 수 있습니다.

Outlook 문제 처리

Outlook은 다양한 문제를 겪을 수 있습니다. 최악의 상황은 Outlook 손상이어야합니다. Outlook 파일이 손상되어 백업이있는 경우 쉽게 복원 할 수 있습니다. 손상된 Outlook 데이터 백업에서. 그러나 백업이없는 경우 손상된 Outlook 파일을 복구해야합니다. 이 경우 기본 제공 복구 도구 인 Scapst.exe를 사용하거나 다음과 같은 더 숙련 된 도구를 사용할 수 있습니다. DataNumen Outlook Repair.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. 수리 SQL Server mdf 데이터베이스 문제 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM