Outlook의 모든 회신 및 전달에 전자 메일 범주를 자동으로 적용하는 방법

Outlook 솔루션 2025 년 9 월 29 일

이메일을 회신하거나 전달할 때 동일한 범주를 적용 할 수 있습니다. 이 기사에서는 VBA 코드로이를 실현하는 방법을 알려드립니다.

모든 회신 및 전달에 원본 전자 메일의 동일한 색상 범주를 할당하는 데 익숙한 경우 Outlook에서이를 자동으로 수행하지 않는 이유는 무엇입니까? Outlook은 이러한 직접적인 기능을 제공하지 않지만 VBA 코드를 사용하여 얻을 수 있습니다. 다음에서는 자세한 단계와 코드를 공개합니다.

모든 회신 및 전달에 전자 메일 범주 자동 적용

처음에는 Outlook 응용 프로그램을 시작하십시오.
그런 다음 "Alt + F11"키를 눌러 Outlook VBA 편집기를 실행합니다.
다음으로 다음 VBA 코드를 "ThisOutlookSession"프로젝트에 복사합니다.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

그 후, 입술tar이 프로젝트를 활성화하려면 Outlook을 선택하십시오.
그 이후로 아래 단계에 따라 시도해 볼 수 있습니다.

먼저 이메일을 선택하고 "전달"버튼을 누르십시오.
그런 다음 "옵션"탭으로 이동하여 "추가 옵션"그룹의 오른쪽 하단 모서리에있는 확장 아이콘을 누를 수있는 전달 이메일이 표시됩니다.
다음으로 팝업 "속성"대화 상자에서이 이메일이 원본 이메일과 동일한 색상 범주로 할당되었음을 확인할 수 있습니다.

손상된 Outlook 파일 수정

Outlook이 취약하다는 사실을 감안할 때 Outlook 데이터 손실을 방지하기 위해 많은 조치를 취해야합니다. 예를 들어 정기적으로 데이터를 백업해야합니다. 또한 포함 된 링크 나 첨부 파일을 포함하여 알려지지 않은 이메일에주의해야합니다. 마지막으로, 다음과 같은 첨단 외부 수정 도구를 가져와야합니다. DataNumen Outlook Repair. 최대 데이터를 검색하는 데 도움이 될 수 있습니다. 손상된 Outlook 파일.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL Server 고정 된 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM