Outlook에서 회신 할 때 원본 이메일 첨부 파일을 유지하는 6 가지 방법

많은 사용자가 전자 메일에 회신 할 때 원본 전자 메일 첨부 파일을 유지하도록 Outlook을 구성하려고합니다. 이 기사에서는 VBA를 사용하여 자동으로 실현하는 현명한 방법과 함께 5 가지 해결 방법을 제공합니다.

전자 메일에 회신 할 때 원본 첨부 파일을 유지하는 기본 기능이 Outlook에 없다고 불평하는 사용자가 많습니다. 따라서 여기에서는 6 가지 방법을 공유합니다. 그 중 하나는 VBA를 사용하여 Outlook을 사용하여 회신 이메일에 원본 첨부 파일을 자동으로 첨부하는 것이므로 매우 유용합니다. 이제 자세히 읽어보십시오.

1. 원본 이메일을 첨부하여 회신

Outlook은 전자 메일에 회신 할 때 원본 전자 메일 첨부 파일을 유지하는 기능을 제공하지 않지만 사용자는 원본 전자 메일을 첨부 된 상태로 유지할 수 있습니다. 따라서 선택적인 해결 방법입니다. "파일"> "옵션"> "메일"> "답장 및 전달"섹션으로 이동하여 회신 설정을 변경할 수 있습니다. 자세한 내용은 이전 기사를 참조하시기 바랍니다.“Outlook에서 원본 첨부 파일로 회신하는 5 단계”. 그러나 여전히 원본 첨부 파일 만 유지하고 싶다면 다른 방법을 배우십시오.

2. 첨부 파일을 수동으로 끌어서 놓기

1. 에tar그런 다음 소스 이메일을 두 번 클릭하여 자체 창에서 엽니 다.
2. 그런 다음 "답장"버튼을 클릭하면 답장 이메일이 나타납니다.
3. 다음으로 같은 화면에서 볼 수있을 때까지 두 개의 메시지 창을 모두 축소해야합니다.
4. 그런 다음 원본 이메일의 모든 첨부 파일을 선택하십시오.
5. 마지막으로 회신 이메일의 "첨부 됨"줄에 끌어다 놓습니다.

3. 수동으로 첨부 파일 복사 및 붙여 넣기

1. 우선 소스 이메일을 연 후 모든 첨부 파일을 선택하십시오.
2. 그런 다음 "첨부 파일"탭에서 "복사"버튼을 클릭합니다.
3. 그 후“메시지”탭에서“답장”버튼을 클릭하면 회신 메일이 열립니다.
4. 최종적으로 회신 이메일에서 "첨부 됨"줄을 클릭하고 "Ctrl + V"버튼을 눌러 이전에 복사 한 첨부 파일을 붙여 넣습니다.

4. 이메일 전달 및 수신자 입력

1. 먼저 이러한 이메일을 선택한 다음 리본에서 "전달"버튼을 클릭합니다.
2. 새로 팝업 메시지 창에서 원본 첨부 파일이 유지됩니다. 이제 원본 이메일을 보낸 사람에게 "받는 사람"필드를 입력해야합니다.
3. 선택적으로 필요에 따라 주제를 변경할 수 있습니다.

5.이 이메일 재전송 및 수신자 변경

1. 우선 소스 이메일을 엽니 다.
2. 그런 다음 "Move"그룹에서 "Actions"버튼을 클릭합니다.
3. 그런 다음 드롭 다운 목록에서 "이 메시지 다시 보내기"를 선택합니다.
4. 원래 보낸 사람이 아니라는 경고를받을 수 있습니다. 그냥 무시하고 "예"를 누르십시오.
5. 이후의 새 이메일에서 "받는 사람"필드를 원래 이메일의 보낸 사람으로 수정해야합니다.
6. 또한 이메일 계정을 사용하여 전송을 자신의 계정으로 변경하는 것을 잊지 마십시오.

6. VBA를 통해 원본 첨부 파일 자동 추가

솔직히 말해서 위에서 언급 한 모든 접근 방식은 해결 방법입니다. 회신 할 때 Outlook이 원본 첨부 파일을 자동으로 유지하도록하려면이 방법을 사용할 수 있습니다.

1. 기본 Outlook 창에서 "Alt + F11"키를 누릅니다.
2. 그런 다음 "Microsoft Visual Basic for Applications"창에서 아래의 VBA 코드를 "ThisOutlookSession"프로젝트에 복사합니다.

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

3. 나중에이 매크로에 서명하고 서명 된 매크로를 허용하도록 Outlook 매크로 설정을 변경합니다.
4. 그 후, 입술tar이 VBA 프로젝트를 활성화하려면 Outlook 응용 프로그램을 사용하십시오.
5. 이제부터는“답장”버튼을 클릭 할 때마다. 회신 이메일은 원본 첨부 파일과 함께 한 번에 표시됩니다.

탁월한 수리 도구 사용

Outlook은 무수한 기능으로 인해 다른 이메일 클라이언트보다 우위에 있습니다. 그러나 여전히 부패하기 쉽습니다. 따라서 건강에 더 많은 관심을 기울여야합니다. 일반적으로 사소한 문제가 발생하면 기본 제공 수정 유틸리티를 사용하기 만하면됩니다. 그럼에도 불구하고 심각한 문제를 겪는다면 다음과 같은 훨씬 더 능숙한 도구를 사용하는 것이 좋습니다. DataNumen Outlook Repair. 그것은 수 Outlook 수정 즉시 파일.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. SQL 수정 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COM