문서의 텍스트 상자, 각주 및 미주와 관련된 단어 수 통계를 얻는 3 가지 방법

워드 솔루션 2025 년 9 월 28 일

오늘 기사에서는 문서의 텍스트 상자, 각주 및 미주와 관련된 단어 수 통계를 얻는 3 가지 빠른 방법이 있습니다.

문서의 총 단어 수를 얻는 것은 어렵지 않습니다. 그러나 다른 종류의 텍스트의 단어 수를 얻으려면 더 많은 작업이 필요합니다. 다음은 3 가지 방법입니다. 무엇을 사용할 수 있는지 계속 읽으십시오.

방법 1 : 텍스트 상자, 각주 및 미주의 텍스트를 포함하는 단어 계산

기본적으로 Word는 텍스트 상자의 텍스트와 각주 및 미주의 단어를 포함하여 문서에 나타나는 모든 단어를 계산합니다.

첫 번째와 포름ost, 상태 표시 줄로 이동하여 "단어"를 클릭하여 "단어 수"상자를 엽니 다.
거기에서 모든 종류의 통계를 볼 수 있습니다. "텍스트 상자, 각주 및 미주 포함"상자를 선택했는지 확인하십시오.
그런 다음 "닫기"를 클릭합니다.
상태 표시 줄에서 "단어"명령을 찾을 수없는 경우 해당 위치를 마우스 오른쪽 버튼으로 클릭하십시오.
다음으로 "단어 수"를 확인하십시오.

방법 2 : 텍스트 상자, 각주 및 미주에서 단어 수에서 텍스트 제외

이것은 방법 1과 반대입니다. 따라서 "텍스트 상자, 각주 및 미주 포함"상자의 선택을 취소하면됩니다.

방법 3 : Word 매크로를 실행하여 텍스트 상자, 각주 및 미주에서 개별 단어 수 가져 오기

먼저 방법 1의 방법을 사용하여 "단어 수"상자를 트리거하고 옵션 상자가 선택되어 있는지 확인합니다.
그런 다음 "Alt + F11"을 눌러 VBA 편집기를 엽니 다.
그런 다음 먼저 "Normal"을 클릭하여 "Normal"프로젝트에 새 모듈을 삽입합니다.
그리고 다음 "삽입"을 클릭합니다.
그런 다음 "모듈"을 선택합니다.
모듈을 두 번 클릭하여 코딩 영역을 열고 여기에 다음 코드를 붙여 넣습니다.

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub