Outlook 이메일의 모든 테이블을 빠르게 인쇄하는 2 가지 방법

Outlook 전자 메일의 다른 텍스트없이 모든 표를 빠르게 인쇄하려면 두 가지 방법 중 하나를 사용하여 수행 할 수 있습니다.

메시지 본문에 많은 테이블이 포함 된 이메일을 받으면 때때로 이러한 테이블을 추출하여 본문에 텍스트없이 인쇄 만 할 수 있습니다. 그러나 Outlook에는이를 달성하기위한 관련 기능이 없습니다. 따라서 다음에서 우리는 두 가지 수단을 공유 할 것입니다.

방법 1 : 별도의 페이지에 모든 표 인쇄

1. 에tart와 함께 Outlook 프로그램을 시작하십시오.
2. 그런 다음 기본 Outlook 창에서 "Alt + F11"키 버튼을 누릅니다.
3. 다음 "Microsoft Visual Basic for Applications"창에서 사용하지 않는 모듈을 찾아서 열 수 있습니다.
4. 그 후 다음 VBA 코드를이 모듈에 복사해야합니다.

Sub PrintAllTables_inOutlookEmail_Individually()
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objTable As Word.Table
    Dim lTableCount As Long
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim i As Long
 
    'Get the Source Mail
    Set objMail = Outlook.Application.ActiveExplorer.Selection.Item(1)
    Set objMailDocument = objMail.GetInspector.WordEditor
    lTableCount = objMailDocument.Tables.count
 
    Set objWordApp = CreateObject("Word.Application")
    objWordApp.Visible = True
 
    For i = 1 To lTableCount
        Set objTable = objMailDocument.Tables(i)
        objTable.Range.Copy
 
        'Copy Each Table into Each Word Document
        Set objWordDocument = objWordApp.Documents.Add
        objWordDocument.Content.Paste
 
        'Print Out Each Document
        objWordDocument.PrintOut
 
        objWordDocument.Close False
    Next
 
    objWordApp.Quit
End Sub

5. 나중에 새 VBA 프로젝트를 빠른 실행 도구 모음에 추가해야합니다. "Outlook 옵션"> "빠른 액세스 도구 모음"탭으로 이동하여이를 달성하십시오.
6. 마지막으로 촬영할 수 있습니다.

• 먼저 여러 테이블이 포함 된 이메일을 선택하십시오.
• 그런 다음 빠른 실행 도구 모음에서 새 매크로 버튼을 클릭합니다.
• 한 번에 모든 표가 개별 페이지에 인쇄됩니다.

방법 2 : 모든 표를 시리즈로 인쇄

1. 먼저 위의 1 ~ 2 단계에 따라 "Microsoft Visual Basic for Applications"창으로 이동합니다.
2. 그런 다음 사용하지 않는 모듈에 액세스하여 다음 VBA 코드를 복사해야합니다.

Sub PrintAllTables_inOutlookEmail_Continuously()
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objTable As Word.Table
    Dim lTableCount As Long
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objCell As Word.Cell
 
    Set objMail = Outlook.Application.ActiveExplorer.Selection.Item(1)
    Set objMailDocument = objMail.GetInspector.WordEditor
 
    'Create a Word Document
    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Add
    objWordDocument.Activate
    objWordApp.Visible = True
 
    For Each objTable In objMailDocument.Tables
        objTable.Range.Copy
 
        'Copy All Tables into One Word Document
        With objWordDocument.Range
             .Collapse wdCollapseEnd
             .PasteSpecial wdPasteRTF
             .Text = vbCrLf
        End With
    Next
 
    'Print out the Word Document
    objWordDocument.PrintOut
    objWordDocument.Close False
    objWordApp.Quit
End Sub

3. 나중에 빠른 실행 도구 모음에 새 매크로를 추가 할 수 있습니다.
4. 결국 소스 메일을 선택하고 빠른 실행 도구 모음에서 매크로 버튼을 누릅니다. 즉시이 이메일의 모든 표가 하나의 Word 문서로 복사되며 지금 인쇄됩니다.

손상으로부터 Outlook 데이터 보호

수많은 기능에도 불구하고 Outlook은 오류, 충돌 및 손상으로부터 벗어날 수 없습니다. 따라서 충돌이 발생하면 Outlook 데이터가 작별 인사를하는 경향이 있습니다. 따라서 방지하기 위해 Outlook 손상, 숨겨진 바이러스 차단, Outlook을 올바르게 닫는 등의 노력이 필요합니다. 또한 다음과 같은 숙련 된 수리 도구를 확보하는 것이 현명합니다. DataNumen Outlook Repair.

저자 소개 :

Shirley Zhang은 데이터 복구 전문가입니다. DataNumen, Inc.는 다음과 같은 데이터 복구 기술 분야의 세계적 리더입니다. mdf 수정 및 전망 수리 소프트웨어 제품. 자세한 내용은 WWW.datanumen.COMc