PSTファイル内のすべてのフォルダのサイズ情報をExcelファイルにすばやくエクスポートする方法

Outlookソリューション 2025 年 9 月 29 日

PSTファイル内の各フォルダーのサイズ情報を確認する場合は、この記事で公開されている方法を使用できます。 PSTファイル内のすべてのフォルダのサイズ情報をExcelファイルにすばやくエクスポートします。

PSTファイルが大きすぎる場合は、各フォルダーのサイズを確認することをお勧めします。どちらが大きいかを簡単に特定し、サイズに基づいて適切なアーカイブを行うのに役立ちます。通常、フォルダのサイズを確認するには、フォルダを右クリックして「プロパティ」を選択するだけです。新しいポップアップダイアログボックスで、「フォルダサイズ」ボタンをクリックできます。ただし、多数のフォルダを作成している場合、サイズ情報をXNUMXつずつ手動で確認するのはかなり面倒です。したがって、PSTファイル内のすべてのフォルダーのサイズ情報をバッチで取得する場合は、次のVBAコードを使用できます。すべてのフォルダ名とサイズ情報を一度にExcelファイルにエクスポートします。

PSTファイル内のすべてのフォルダのサイズ情報をExcelファイルにエクスポートする

にtarで、Outlookアプリケーションを起動します。
次に、「開発者」タブに切り替えて「Visual Basic」ボタンをクリックするか、「Alt + F11」キーを押してVBAエディターにアクセスします。
次に、「Microsoft Visual Basic for Applications」ウィンドウで、使用されていないモジュールを開きます。
続いて、次のVBAコードをコピーしてこのモジュールに貼り付けます。

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

その後、Outlookマクロのセキュリティレベルを低く設定する必要があります。
最終的には、試してみることができます。

現在のマクロウィンドウでF5キーボタンを押します。
次に、次の画像のようなPSTファイルを選択するように求められます。
ソースファイルを選択すると、Outlookはサイズ情報のExcelへのエクスポートを開始します。
マクロが終了すると、以下のスクリーンショットのようなメッセージが表示されます。
最後に、事前定義されたローカルフォルダでExcelファイルを見つけることができます。 Excelファイルは次のようになります。

頻繁なPSTエラーに対処する

Outlookはエラーが発生しやすいため、Outlookで多くの問題が発生したことがあるかもしれません。イライラするPSTのトラブルに、より適切かつ柔軟に対処するために、経験豊富で信頼できる修正ユーティリティを近くに置いておくことをお勧めします。 DataNumen Outlook Repair。できます PSTを修正そよ風のような問題。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQL Server 回復と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com