VBAを介してあるOutlookPSTファイルから別のOutlookPSTファイルにフォルダ構造をすばやくコピーする方法

Outlookソリューション 2025 年 9 月 29 日

あるOutlookPSTファイルから別のOutlookPSTファイルにフォルダー構造をコピーする場合は、この記事で紹介した方法を使用できます。この方法では、VBAを使用して一度に取得する方法を説明します。

おそらく、電子メールをより適切に管理するために、メインのOutlookファイルにいくつかのカスタムフォルダーを作成しました。したがって、新しいOutlook PSTファイルを作成するときに、同じフォルダー構造を適用することをお勧めします。実際、私の前回の記事では–「新しいOutlookファイルで現在のフォルダー階層を維持するための2つの手順」では、「アーカイブ」機能を使用してそれを実現する従来の方法を学ぶことができます。それにもかかわらず、実際には、それはまだ少し退屈です。それと比較して、VBAコードを使用して取得する方がはるかに高速です。したがって、以下では、詳細な手順とコードについて説明します。

あるOutlookPSTファイルから別のOutlookPSTファイルにフォルダ構造をコピーする

まず最初に、Outlookプログラムを起動してください。
次に、Outlookウィンドウで、「Alt + F11」キーボタンを押します。
次に、OutlookVBAエディターウィンドウに入ります。
続いて、次のVBAコードをコピーして新しいモジュールに貼り付けます。

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

その後、マクロのセキュリティレベルを低に変更します。
後でVBAエディタウィンドウに戻り、「F5」キーボタンを押してマクロを実行します。
最後に、マクロの動作が終了すると、「Completed！」というメッセージが表示されます。
この時点で、メールナビゲーションペインに移動できます。次の画像のように、ソースPSTファイルと同じフォルダー構造にある新しいOutlookデータファイルが表示されます。

意欲をそそるPSTトラブルに対処する

Outlook PSTはエラーが発生しやすいため、多くの人はOutlookでさまざまな問題に遭遇したことがあるはずです。それらに直面して、あなたは最初に試してみるためにOutlookの受信トレイ修復ツールを使用することができます。失敗した場合は、次のようなより強力なサードパーティツールを適用できます。 DataNumen Outlook Repair、そのことができます Outlookを修正するそよ風のようなPSTエラー。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQL Server 修正しますと見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com