Outlookですべての開封確認を一括削除する方法

Outlookソリューション 2025 年 9 月 29 日

受信者がメールを読んだことを確認するために、メール作成時に開封確認を要求することができます。この場合、受信トレイに開封確認メールが大量に届く可能性があります。この記事では、それらを一括で完全に削除する方法を説明します。

記事を読んだ後「Outlookのすべての配達領収書をバッチ削除する方法「、すべての開封確認を一括削除する方法を考えるかもしれません。実際、XNUMX種類の領収書の明らかな違いはその主題です。配達領収書の件名には「配達済み」が含まれていますが、開封確認には代わりに「読み取り」が含まれています。したがって、同じ方法を使用して、すべての開封確認を一括削除できます。以下では、具体的な手順を詳しく説明します。

すべての開封確認をバッチ削除する

まず最初に、Outlookを起動してください。
次に、「Alt + F11」を使用して、「Alt + FXNUMX」を使用してOutlookVBAエディターに移動します。OutlookでVBAコードを実行する方法"
次に、新しいウィンドウで、空のモジュールを開き、次のコードをそのモジュールに挿入します。

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

その後、最初のサブルーチンをクリックします。
最後に「F5」キーボタンを押します。
一度に、マクロはOutlookからすべての開封確認を削除するように機能します。
完了すると、以下のスクリーンショットのように、結果に関するプロンプトが表示されます。
現在、メールフォルダを確認できます。開封確認はすべてなくなりました。

Outlookデータを守る

Outlookファイルは確かに破損しやすいですが、それを保護するための措置を講じることができます。たとえば、Outlookファイルを小さいサイズに保ち、悪意のある要因から保護し、定期的にバックアップする必要があります。最後になりましたが、次のような強力な外部PST修復ツールを準備することをお勧めします。 DataNumen Outlook Repair。修理に大きな影響を与えます破損したOutlook ファイルにソフトウェアを指定する必要があります。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQL修復と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com