Outlookで特定のCC受信者の電子メールを自動移動する方法

Outlookソリューション 2025 年 9 月 29 日

実際には、ほとんどの方はOutlookルールを作成して、特定のCC受信者を含むメールを自動的に移動させたいと考えているでしょう。しかし、OutlookルールはCC受信者のチェックをサポートしていません。そこで、この記事ではOutlook VBAを使ってそれを実現する方法を解説します。

明らかに、特定の CC 受信者を検索する Outlook ルールを作成することは不可能です。次のスクリーンショットに示すように、受信したメールについては、CC ボックスに自分の名前が入っているかどうかのみを確認できます。同様に、送信メールについても、CC ボックスをチェックするルール条件はありません。

したがって、特定の CC 受信者が含まれる電子メールを自動的に移動するように Outlook を構成したい場合は、他の手段を探す必要があります。それから。ここでは、Outlook VBA を使用してこれを実現する方法を説明します。

特定の CC 受信者を持つ送信済みメールを自動移動する

まず、「開発」タブに移動し、「Visual Basic」ボタンをクリックします。
次に、「ThisOutlookSession」プロジェクトを開き、次の VBA コードをコピーします。

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

その後、このコードに署名し、通常どおりマクロ設定を変更する必要があります。
最後に、「Visual Basic」ウィンドウを終了します。その後、特定の CC 受信者を持つ電子メールは、指定したメールフォルダーに移動されます。

特定の CC 受信者を持つ受信メールを自動移動する

上記の VBA コードは、特定の CC 受信者を持つ送信メールを移動することを目的としています。受信メールで特定の CC 受信者を探して移動したい場合は、代わりに次のコードを使用する必要があります。

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Outlookの破損に備えてください

Outlook は機能が豊富ですが、それでも破損を免れることはできません。したがって、あらゆる潜在的なリスクに対して警戒を続ける必要があります。間違いなく、重要な手順は、Outlook データの一貫性のある最新のバックアップを作成することです。さらに、破損した Outlook 回復ツール近くにある。バックアップと Scanpst.exe の両方が失敗した場合に役立ちます。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。修理 SQL Server MDFファイルエラーと見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com