Outlookで返信するときに元の電子メールの添付ファイルを保持する6つの方法

Outlookソリューション 2025 年 9 月 29 日

多くのユーザーは、電子メールに返信するときに元の電子メールの添付ファイルを保持するようにOutlookを構成することを望んでいます。この記事では、5つの回避策と、VBAを使用して自動的に実現するスマートな方法について説明します。

Outlookには、電子メールに返信するときに元の添付ファイルを保持するためのネイティブ機能がないという不満を多くのユーザーが聞いています。したがって、ここでは6つの方法を紹介します。そのうちのXNUMXつは、VBAを使用してOutlookに元の添付ファイルを返信メールに自動添付させるため、非常に便利です。それらを詳細に理解するために読んでください。

1.元のメールを添付して返信する

Outlookには、電子メールに返信するときに元の電子メールの添付ファイルを保持する機能はありませんが、ユーザーは元の電子メールの添付ファイルを保持できます。したがって、これはオプションの回避策です。「ファイル」>「オプション」>「メール」>「返信と転送」セクションに移動して、返信設定を変更できます。詳細については、私の以前の記事を参照することをお勧めします–「Outlookで元の添付ファイルを使用して返信する5つの手順」。ただし、元の添付ファイルのみを保持したい場合は、他の方法を学習してください。

2.添付ファイルを手動でドラッグアンドドロップします

まず、該当する送信元メールをダブルクリックして、別のウィンドウで開いてください。
次に、「返信」ボタンをクリックすると、返信メールが表示されます。
次に、同じ画面に表示されるまで、XNUMXつのメッセージウィンドウの両方を縮小する必要があります。
その後、元の電子メールのすべての添付ファイルを選択します。
最後に、返信メールの「添付」行にドラッグアンドドロップします。

3.添付ファイルを手動でコピーして貼り付ける

まず、ソースメールを開いた後、すべての添付ファイルを選択します。
次に、「添付ファイル」タブの下の「コピー」ボタンをクリックします。
その後、「メッセージ」タブの「返信」ボタンをクリックして、返信メールを開きます。
最終的に、返信メールで「添付」行をクリックし、「Ctrl + V」ボタンを押して、以前にコピーした添付ファイルを貼り付けます。

4.メールの転送と受信者の入力

まず、そのようなメールを選択してから、リボンの[転送]ボタンをクリックします。
新しくポップアップしたメッセージウィンドウでは、元の添付ファイルが保持されます。次に、元の電子メールの送信者に「宛先」フィールドに入力する必要があります。
オプションで、必要に応じて件名を変更できます。

5.このメールを再送して受信者を変更する

まず、ソースメールを開きます。
次に、「移動」グループの「アクション」ボタンをクリックします。
次に、ドロップダウンリストから「このメッセージを再送信」を選択します。
おそらく、あなたは元の送信者ではないというアラートを受け取るでしょう。それを無視して「はい」を押してください。
後続の新しい電子メールでは、「宛先」フィールドを元の電子メールの送信者に変更する必要があります。
また、メールアカウントを使用して送信を自分のアカウントに変更することを忘れないでください。

6.VBAを介して元の添付ファイルを自動追加

上記のすべてのアプローチは、正直なところ、回避策です。 Outlookが返信時に元の添付ファイルを自動的に保持できるようにしたい場合は、この方法を使用できます。

Outlookのメインウィンドウで、「Alt + F11」キーを押します。
次に、「Microsoft Visual Basic for Applications」ウィンドウで、以下のVBAコードを「ThisOutlookSession」プロジェクトにコピーします。

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

後でこのマクロに署名し、Outlookマクロ設定を変更して、署名されたマクロを許可します。
その後、Outlookアプリケーションを再起動して、このVBAプロジェクトを有効にしてください。
これからは、「返信」ボタンをクリックするたびに。返信メールは、元の添付ファイルとともに一度に表示されます。

卓越した修理ツールに頼る

Outlookは、その無数の機能により、他の電子メールクライアントを引き継いでいます。しかし、それでも破損しがちです。したがって、その健康にもっと注意を払う必要があります。一般に、小さな問題が発生した場合は、組み込みの修正ユーティリティに簡単に戻ることができます。それでも、深刻な問題が発生した場合は、次のようなはるかに熟練したツールを使用することをお勧めします。 DataNumen Outlook Repair。それができる Outlookを修正する瞬時にファイル。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 SQL修正と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com