Outlook電子メールのすべての画像添付ファイルをにすばやくエクスポートする方法 PDF File

Outlookソリューション 2025 年 9 月 29 日

Outlook電子メールのすべての画像の添付ファイルをすばやくエクスポートする場合 PDF ファイルの場合、この記事で紹介した方法を使用できます。 VBAコードを利用して、このような「エクスポート」を短時間で実現します。

場合によっては、多くの画像を組み合わせて PDF メールのすべての画像添付ファイルをにエクスポートするようなファイル PDF ファイル。少し難しいですね。しかし、以下では、手間をかけずにこれをすばやく達成できる方法を示します。

メールのすべての画像添付ファイルをにエクスポートする PDF File

としてtart、通常どおりOutlookプログラムを起動します。
次に、Outlookのメインウィンドウで、「Alt + F11」キーボタンをタップします。
続いて、ポップアップ「Microsoft Visual BasicforApplications」ウィンドウが表示されます。
このウィンドウで、使用されていないモジュールにアクセスする必要があります。
次に、次のVBAコードをコピーしてこのモジュールに貼り付けることができます。

Sub ExportAllImageAttachmentsIntoPdfFile()
    Dim objSourceMail As Outlook.MailItem
    Dim objAttachment As Outlook.Attachment
    Dim objWordApp As Word.Application
    Dim objTempDocument As Word.Document
    Dim strImage As String
    Dim objInlineShape As Word.InlineShape
    Dim strPDF As String
 
    Set objSourceMail = Application.ActiveInspector.currentItem
 
    If Not (objSourceMail Is Nothing) Then
 
       Set objWordApp = CreateObject("Word.Application")
       Set objTempDocument = objWordApp.Documents.Add
       objWordApp.Visible = True
       objTempDocument.Activate
 
       strTempFolder = Environ("Temp") & "\" & Format(Now, "yyyymmddhhmmss") & "\"
       MkDir (strTempFolder)
       Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
       For Each objAttachment In objSourceMail.Attachments
           If IsEmbedded(objAttachment) = False Then
              Select Case LCase(objFileSystem.GetExtensionName(objAttachment.filename))
                     Case "jpg", "jpeg", "png", "bmp", "gif"
                           objAttachment.SaveAsFile strTempFolder & objAttachment.filename
              End Select
           End If
       Next
 
       strImage = Dir(strTempFolder & "*.*", vbNormal)

       Do Until Len(strImage) = 0
          With Selection
               .InlineShapes.AddPicture (strTempFolder & strImage)
               .TypeParagraph
               .Collapse Direction:=wdCollapsEnd
               .ParagraphFormat.Alignment = wdAlignParagraphCenter
               .TypeParagraph
          End With
          strImage = Dir()
       Loop

       For Each objInlineShape In objTempDocument.InlineShapes
           objInlineShape.Select
           Selection.ParagraphFormat.Alignment = wdAlignParagraphCenter
           objInlineShape.ScaleHeight = 50
           objInlineShape.ScaleWidth = 50
       Next
 
       'Change the path to save the PDF file
       strPDF = "E:\Image Attachments.pdf"
 
       'Export the temp Word document as a PDF file
       objTempDocument.ExportAsFixedFormat strPDF, wdExportFormatPDF
  
       objTempDocument.Close False
       objWordApp.Quit
 
       MsgBox "Complete!" 
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

その後、現在のウィンドウを閉じることができます。
後で、「ファイル」>「オプション」>「クイックアクセスツールバー」に移動できます。これで、クイックアクセスツールバーに新しいマクロを追加できます。
最終的には、このマクロを試すことができます。

まず、画像の添付ファイルをエクスポートするメールを開きます。 PDF ファイルにソフトウェアを指定する必要があります。
次に、クイックアクセスツールバーのマクロボタンをクリックします。
マクロが完了すると、メッセージが表示されます。
その後、事前定義されたローカルフォルダに移動して、 PDF 開いている電子メールに添付されているすべての画像を含むファイル。

侵害されたOutlookデータを取得する

Outlookが破損した場合は、破損したデータを回復するための努力をする必要があります。この場合、最初に組み込みの修復ツールであるScanpstを試すことができます。 Outlookファイルを修復するタスクではないと仮定すると、次のような外部ツールを利用することもできます。 DataNumen Outlook Repair。復元が得意です破損したOutlook 破損が最小限に抑えられたファイル。

著者紹介：

Shirley Zhangは、のデータ復旧の専門家です。 DataNumen、Inc。は、以下を含むデータ復旧技術の世界的リーダーです。 mdf修理と見通し修理ソフトウェア製品。詳細については、次のWebサイトをご覧ください。 WWW。datanumen.com