Cara Cepat Menyalin Struktur Folder dari Satu File PST Outlook ke File Lain melalui VBA

Jika Anda ingin menyalin struktur folder dari satu file Outlook PST ke file PST lainnya, Anda dapat menggunakan metode yang diperkenalkan dalam artikel ini, yang akan mengajarkan Anda cara menggunakan VBA untuk mendapatkannya sekaligus.

Mungkin, untuk mengelola email dengan lebih baik, Anda telah membuat beberapa folder khusus di file utama Outlook Anda. Jadi saat membuat file Outlook PST baru, Anda mungkin ingin menerapkan struktur folder yang sama. Sebenarnya, di artikel saya sebelumnya – “2 Langkah untuk Menjaga Folder Saat Ini Tetap Baikrarchy di File Outlook Baru”, Anda dapat mempelajari metode tradisional, yaitu menggunakan fitur “Arsip” untuk mencapainya. Meski begitu, sebenarnya ini masih agak membosankan. Dibandingkan dengan itu, menggunakan kode VBA untuk mendapatkannya akan lebih cepat. Oleh karena itu, berikut ini kami akan memberi tahu Anda langkah-langkah dan kode rumitnya.

Salin Struktur Folder dari Satu File PST Outlook ke File Lainnya

1. Pada awalnya, start program Outlook Anda.
2. Kemudian di jendela Outlook, tekan tombol tombol “Alt + F11”.
3. Selanjutnya Anda akan masuk ke jendela editor Outlook VBA.
4. Selanjutnya salin dan tempel kode VBA berikut ke modul baru.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. Setelah itu, ubah tingkat keamanan makro Anda ke rendah.
6. Kemudian kembali ke jendela editor VBA dan tekan tombol "F5" untuk menjalankan makro.
7. Terakhir, setelah makro selesai bekerja, Anda akan mendapatkan pesan yang meminta “Selesai!”.
8. Pada tahap ini, Anda dapat membuka panel navigasi email. Anda akan melihat File Data Outlook baru yang berada dalam struktur folder yang sama dengan file PST sumber, seperti gambar di bawah ini:

Mengatasi Masalah PST yang Mengecewakan

Karena Outlook PST rawan kesalahan, banyak dari Anda pasti pernah mengalami berbagai masalah di Outlook. Menghadapinya, pertama-tama Anda dapat menggunakan alat perbaikan kotak masuk Outlook untuk mencobanya. Jika gagal, Anda dapat menerapkan alat pihak ketiga yang lebih ampuh, seperti DataNumen Outlook Repair, Yang dapat perbaiki Outlook Kesalahan PST sangat mudah.

Pengantar Penulis:

Shirley Zhang adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk SQL Server memperbaiki dan produk perangkat lunak perbaikan pandangan. Untuk informasi lebih lanjut kunjungi www.datanumen.com