3 Cara Cepat untuk Menghapus Baris dan Kolom Kosong di Tabel Word Anda

Dalam hal iniost, kami akan menjelaskan kepada Anda 3 cara cepat untuk menghapus baris dan kolom kosong di tabel Word Anda.

Tabel sangat penting untuk sebuah dokumen, terutama dalam menampung berbagai jenis data. Terkadang, tabel panjang bisa melebihi satu halaman dan diperpanjang lebih dari beberapa halaman. Jadi, setelah tabel menjadi panjang dan rumit, ada langkah-langkah yang dapat Anda lakukan untuk menyederhanakannya. Misalnya, Anda dapat menghapus baris dan kolom kosong yang tidak perlu.

Berikut adalah 3 metode yang dapat Anda gunakan.

Metode 1: Hapus Baris dan Kolom Kosong Secara Manual

1. Pertama, pilih baris atau kolom kosong.
2. Kemudian klik kanan untuk mendapatkan menu kontekstual. Pada menu, pilih "Hapus Baris" atau "Hapus Kolom" yang sesuai.

Sayangnya, Anda tidak dapat memilih beberapa baris atau kolom yang tidak berurutan dan menghapusnya bersama-sama dengan cara ini. Untuk permintaan ini, Anda dapat merujuk ke artikel kami sebelumnya: 5 Metode Cepat untuk Menghapus Batch Beberapa Baris atau Kolom di Tabel Word Anda

Metode 2: Hapus Batch Semua Baris dan Kolom Kosong dalam Tabel

Metode 1 ada batasannya. Jadi kami akan menawarkan Anda cara untuk menghapus baris dan kolom dalam tabel melalui kode VBA.

1. Untuk memulainya, letakkan kursor di dalam a tardapatkan meja.
2. Kedua, picu editor VBA dengan menekan "Alt + F11".
3. Di editor, klik proyek "Normal" terlebih dahulu.
4. Kemudian klik tab "Sisipkan" pada bilah menu.
5. Pada menu drop-down, pilih "Module".
6. Klik dua kali pada modul untuk membukanya dan tempel kode berikut di sana:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Terakhir, klik tombol "Run" pada menu bar atau tekan "F5".

Dalam beberapa detik, Anda akan menghapus semua baris dan kolom kosong di tabel itu.

Metode 3: Hapus Batch Semua Baris dan Kolom Kosong di Semua Tabel dalam Dokumen

1. Pertama, ulangi langkah-langkah di metode 2 untuk menginstal dan menjalankan makro.
2. Hanya kali ini, ganti makro tersebut dengan yang berikut ini:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Pulihkan Dokumen yang Rusak

Ada lebih dari satu cara untuk mengambil lost data kembali saat ini. Misalnya, menggunakan cadangan selalu menjadi prioritas utama Anda. Jika itu tidak memenuhi kebutuhan Anda untuk mendapatkan kembali informasi terbaru, Anda dapat mencoba file perbaikan doc tool.

Pengantar Penulis:

Vera Chen adalah pakar pemulihan data di DataNumen, Inc., yang merupakan pemimpin dunia dalam teknologi pemulihan data, termasuk perbaikan xlsx dan pdf memperbaiki produk perangkat lunak. Untuk informasi lebih lanjut kunjungi www.datanumen.com