Hogyan lehet gyorsan exportálni egy Outlook mappát az összes almappával és elemmel egy Windows mappába

Időnként érdemes lehet egy Outlook mappát az összes almappával és elemmel egy Windows mappába köteggel exportálni. Ez a cikk egy ilyen módszert ismertet meg, amely az Outlook VBA alkalmazását jelenti.

Ha egy Outlook mappát szeretne exportálni a helyi meghajtóra, az összes elemet ugyanabban a mappastruktúrában, ha a manuális mentést és exportálást választja, sok időt vesz igénybe. Ezért miért nem folyamodik más eszközökhöz, például bármilyen exportáló eszközhöz vagy VBA-kódhoz? Itt egy ilyen VBA-kódrészletet mutatunk be Önnek. Lehetővé teszi, hogy úgy érje el, mint egy szellő.

Exportálja az Outlook mappában lévő összes almappát és elemet egy Windows mappába

1. Legelőször indítsa el az Outlook programot.
2. Ezután az Outlook főablakában nyomja meg az „Alt + F11” billentyűparancsokat.
3. Ezt követően megjelenik a „Microsoft Visual Basic for Applications” ablak.
4. Ezután meg kell nyitnia egy üres modult, és be kell másolnia a következő VBA kódokat.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Ezt követően meg kell győződnie arról, hogy az Outlook engedélyezi a makrókat a makróbeállításokban.
6. Végül megpróbálhatod.

• Először is térjünk vissza az új makró ablakhoz.
• Ezután kattintson az „ExportFolderWithAllItems” szubrutinra.
• Ezután nyomja meg az F5 billentyűt a makró futtatásához.
• Ezt követően ki kell választania egy adott mappát.
• Végül, amikor a „Complete” üzenetet kapja, hozzáférhet az előre meghatározott helyi mappához. Az összes elemet ugyanabba a mappastruktúrába mentette.

Az Outlook összeomlásából eredő adatvesztés megelőzése

Talán már találkoztál is Outlook-összeomlásokkal. Az újraindítás után az Outlook legtöbbször a megszokott módon fog működni. Előfordulhat azonban, hogy a PST-fájlunk megsérül. Ilyenkor érdemes megpróbálni visszaállítani a PST-adatokat, például egy tapasztalt eszközt, például a ...-t. DataNumen Outlook Repair. Képes javítsa ki az Outlookot hibákat, és kivonja az adatokat a kompromittált PST-fájlból anélkül, hogy izzadna.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve SQL Server javítás és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com