A PST-fájlban lévő összes mappa méretinformációinak gyors exportálása Excel-fájlba

Ha szeretné ellenőrizni a PST-fájl egyes mappáinak méretinformációit, használhatja a cikkben ismertetett módszert. Gyorsan exportálja a PST-fájlban lévő összes mappa méretinformációját Excel-fájlba.

Ha a PST-fájl túl nagy, érdemes ellenőrizni az egyes mappák méretét. Segítségével könnyen kitalálhatja, melyek a nagyobbak, és megfelelő archiválást végezhet a méret alapján. Általában a mappa méretének ellenőrzéséhez egyszerűen kattintson jobb gombbal egy mappára, majd válassza a „Tulajdonságok” lehetőséget. Az új felugró párbeszédpanelen kattintson a „Mappa mérete” gombra. Ha azonban sok mappát hozott létre, akkor a méretadatok manuális ellenőrzése jelentős nehézségeket okoz. Tehát, ha kötegelt formában szeretné megkapni a PST-fájlban található összes mappa méretinformációit, használhatja a következő VBA-kódot. Egyszerre exportálja az összes mappanevet és méretinformációt egy Excel-fájlba.

Exportálja a PST-fájlban lévő összes mappa méretadatait egy Excel-fájlba

1. Kezdésként indítsa el az Outlook alkalmazást.
2. Ezután váltson a „Fejlesztő” fülre, és kattintson a „Visual Basic” gombra, vagy nyomja meg az „Alt + F11” billentyűket a VBA-szerkesztő eléréséhez.
3. Ezután a „Microsoft Visual Basic for Applications” ablakban nyissa meg a nem használt modult.
4. Ezt követően másolja ki és illessze be a következő VBA-kódokat ebbe a modulba.

Dim strExcelFile As String
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet

Sub ExportFodlerSizetoExcel()
    Dim objSourcePST As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
    objExcelWorksheet.Cells(1, 1) = "Folder"
    objExcelWorksheet.Cells(1, 2) = "Size"
 
    'Select a source PST file
    Set objSourcePST = Outlook.Application.Session.PickFolder

    For Each objFolder In objSourcePST.Folders
        Call ProcessFolders(objFolder)
    Next
 
    'Fit the columns from A to B
    objExcelWorksheet.Columns("A:B").AutoFit
 
    strExcelFile = "E:\Outlook\" & objSourcePST.Name & " Folder Size (" & Format(Now, "yyyy-mm-dd hh-mm-ss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder)
    Dim objItem As Object
    Dim lCurrentFolderSize As Long
    Dim nNextEmptyRow As Integer
 
    objCurrentFolder.Items.SetColumns ("Size")
    For Each objItem In objCurrentFolder.Items
        lCurrentFolderSize = lCurrentFolderSize + objItem.Size
    Next
 
    'Convert byte to kilobyte
    'To convert to megabyte, use:
    'lCurrentFolderSize = (lCurrentFolderSize / 1024) / 1024
    lCurrentFolderSize = lCurrentFolderSize / 1024
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1

    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = objCurrentFolder.FolderPath
    objExcelWorksheet.Range("B" & nNextEmptyRow) = lCurrentFolderSize & " KB"
 
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder)
       Next
    End If
End Sub

5. Ezt követően állítsa alacsonyra az Outlook makró biztonsági szintjét.
6. Végül megpróbálhatod.

• Nyomja meg az F5 billentyűt az aktuális makró ablakban.
• Ezután a rendszer felkéri, hogy válasszon egy PST-fájlt, például a következő képet:
• A forrásfájl kiválasztása után az Outlook megkezdi a méretadatok exportálását az Excelbe.
• A makró befejezése után az alábbi képernyőképhez hasonló üzenetet kap.
• Végül megtalálhatja az Excel fájlt az előre meghatározott helyi mappában. Az Excel fájl a következőképpen fog kinézni:

Kezelje a gyakori PST-hibákat

Mivel az Outlook hajlamos a hibákra, előfordulhat, hogy valaha is sok probléma volt az Outlookban. A frusztráló PST-problémák jobb és rugalmasabb kezelése érdekében tanácsos a közelben tartani egy tapasztalt és jó hírű javítási segédprogramot, mint pl. DataNumen Outlook Repair. Képes javítsd ki a PST-t problémák, mint egy szellő.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve SQL Server felépülés és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com