Hogyan lehet gyorsan csatolni egy Word-dokumentum bizonyos oldalait egy Outlook e-mailhez

Az MS Word közvetlen funkcióval rendelkezik, amely támogatja a felhasználókat, hogy az aktuális Word-dokumentumot e-mail mellékletként küldjék el. De néha csak abban reménykedhet, hogy egy Word-dokumentum adott oldalait csatolja egy Outlook e-mailhez. Most ez a cikk egy módszert oszt meg veled.

Ha egy teljes Word-dokumentumot e-mail mellékletként szeretne elküldeni az MS Word alkalmazásban, egyszerűen lépjen a „Fájl” menübe, és lépjen a „Mentés és küldés” fülre, amely alatt található a „Küldés mellékletként” gomb. Időnként azonban előfordulhat, hogy a küldeni kívánt dokumentum csak bizonyos oldalai a dokumentumnak. Ebben a helyzetben az alábbiakban bemutatott módszert használhatja ennek megvalósítására.

Csatolja egy Word-dokumentum adott oldalait egy e-mailhez

1. Először is meg kell nyitnia azt a Word forrásdokumentumot, amelynek konkrét oldalait e-mailben szeretné elküldeni.
2. Ezután, miután belépett az MS Word ablakába, meg kell nyomnia az „Alt + F11” billentyűket.
3. Ezután hozzáférhet az MS Word VBA-szerkesztőjéhez.
4. Ezután engedélyeznie kell a „Microsoft Outlook objektumtárat”. Ehhez kattintson az „Eszközök” > „Referencia” menüpontra.
5. Ezt követően át kell másolnia a következő VBA-kódot egy nem használt modulba.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Végül futtathatja ezt a makrót. Csak nyomja meg az F5 billentyűt, vagy érintse meg a „Futtatás” ikont az eszköztáron.
7. A makró befejezése után egy új Outlook e-mail jelenik meg, amely csatolva van a forrás Word-dokumentum kivonatával, például a következő képernyőképen:

Kivonja a maximális adatot a sérült Outlook fájlból

Ha évtizedek óta használja az Outlookot, akkor számos Outlook-problémával szembesülhetett, beleértve a felugró belső hibaüzeneteket, a hirtelen összeomlásokat és a súlyos fájlsérüléseket. Tekintettel arra, hogy a scanpst, beépített javítóeszköz, csak az apró problémákkal tud megbirkózni, jobb, ha kéznél tart egy külső erős javítóeszközt, mondjuk DataNumen Outlook Repair. A sérült Outlook adatfájlból a maximális adatmennyiséget képes kiemelni.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sql javítás és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com