Hogyan lehet gyorsan csatolni az utoljára módosított fájlt egy Windows mappában az Outlook e-mailjéhez

Időnként érdemes gyorsan megkeresni és csatolni az utoljára módosított fájlt egy adott Windows mappában egy Outlook e-mailhez. Ebben az esetben használhatja a cikkben bemutatott módszert.

Néhány felhasználó szeretné, ha az Outlook gyorsan megkeresné és hozzáfűzné az e-mailekhez egy Windows mappában található utoljára módosított fájlt, például a legutóbb létrehozott, módosított vagy mentett fájlt. Az Outlook azonban nem kínál ilyen közvetlen és beépített funkciót. Ezért a következőkben bemutatunk egy VBA kódrészletet, amely ezt könnyedén megvalósítja.

Csatolja az utoljára módosított fájlt egy Windows mappában az e-mailhez

1. Már az elején el kell indítania az Outlook alkalmazást.
2. Ezután, miután belépett az Outlook főablakába, megnyomhatja az „Alt + F11” billentyűket.
3. Ezután sikeresen eléri az Outlook VBA szerkesztő ablakát.
4. Ezt követően meg kell találnia és meg kell nyitnia egy olyan modult, amelyet nem használ.
5. Ezután másolja és illessze be a következő VBA-kódot ebbe a modulablakba.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Ezt követően kiléphet az aktuális VBA-szerkesztő ablakból, és folytathatja az új makró hozzáadását a Gyorselérési eszköztárhoz vagy az Üzenetablak szalagjához.
7. Később az Outlook makró biztonsági szintjét alacsonyra kell módosítania.
8. Végül megpróbálhatod.

• Először is hozzon létre és írjon egy új Outlook e-mailt a szokásos módon.
• Ezután nyomja meg a makró gombot a Gyorselérési eszköztárban, az alábbi képhez hasonlóan:
• Ezután ki kell választania egy forrás Windows mappát, és meg kell nyomnia az „OK” gombot.
• Ha van ilyen fájl a kiválasztott Windows mappában, akkor a következő képernyőképhez hasonló üzenet jelenik meg:
• Ha az „Igen” gombra kattint, ez a fájl azonnal csatolásra kerül.

A lehető leghamarabb oldja meg az Outlook-problémákat

Ha bármilyen Outlook-problémával találkozik, javasoljuk, hogy a lehető leghamarabb oldja meg azokat. Ebben a helyzetben jobb, ha felkészül egy robosztusra Outlook javítás eszközt előre, mint pl DataNumen Outlook Repair. Képes a PST hibák kijavítására és az Outlook-adatok hatékony megmentésére.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sérült mdf és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com