Az összes címzett gyors kibontása több Outlook-üzenet (.msg) fájlból

Néhány felhasználó gyorsan ki szeretné bontani az összes címzettet az Outlook e-mailekből mentett több Outlook-üzenetfájlból. Most ez a post ezt megvizsgálja, hogy megosszon egy gyors megközelítést.

Ha ki szeretné bontani a címzetteket egyetlen Outlook-üzenetfájlból, egyszerűen kattintson duplán a megnyitásához, majd másolja a címzetteket a megnyíló Üzenet ablakba. Ha azonban egy csomó Outlook-üzenetfájllal kell foglalkoznia, a kézi módszer nem elég hatékony. Így sokkal hatékonyabb módszert kereshet. Itt bemutatunk egy ilyet. Olvassa el a részleteket.

Az összes címzett kibontása több Outlook-üzenet (.msg) fájlból

1. Mert minttart, hozzáférhet az Outlook VBA szerkesztőhöz a következő szerintA VBA kód futtatása az Outlookban".
2. Ezután másolja ki és illessze be a következő VBA-kódot egy üres modulba.

Dim strRecipients As String

Sub ExtractRecipientsFromOutlookMSGFiles()
    Dim objShell, objWindowsFolder As Object
 
    strRecipients = ""
    'Select a Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows Folder:", 0, "")
 
    If Not objWindowsFolder Is Nothing Then
       Call ProcessWindowsFolders(objWindowsFolder.self.Path & "\")
       'Display a Message
       MsgBox "Recipients: " & vbCrLf & strRecipients, vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessWindowsFolders(strFolderPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.Recipient
    Dim objSubfolder As Object

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strFolderPath)
 
    For Each objFile In objFolder.Files
        If objFileSystem.GetExtensionName(objFile) = "msg" Then
           Set objItem = Session.OpenSharedItem(objFile.Path)

           If TypeName(objItem) = "MailItem" Then
              Set objMail = objItem
              'Extract recipients' email addresses
              For Each objRecipient In objMail.Recipients
                  strRecipients = strRecipients & objRecipient.Address & vbCr
              Next
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
               Call ProcessWindowsFolders(objSubfolder.Path)
           End If
       Next
    End If
End Sub

3. Ezután mozgassa a kurzort az első szubrutinban.
4. Ezután kattintson a „Futtatás” gombra, vagy nyomja meg az „F5” billentyűt.
5. Ezután a felugró párbeszédpanelen válassza ki azt a Windows mappát, amely az Outlook-üzenet (.msg) forrásfájljait tartalmazza.
6. A kiválasztás után kattintson az „OK” gombra a makró futásának folytatásához.
7. Amikor a makró befejeződik, megjelenik egy üzenet, amely felsorolja az összes kibontott címzett e-mail címét, amint az a következő képernyőképen látható.

Védje Outlook adatait a veszélytől

Az Outlook-adatok bevallottan hajlamosak a korrupcióra. Ezért az Outlook adatok védelme meglehetősen nehézkes feladat. Ehhez kitartónak kell lennie az Outlook-adatok rendszeres biztonsági mentése mellett. Ezenkívül, ha lehetséges, körültekintő és ajánlott egy tapasztalt és professzionális Outlook elkészítése PST javítás eszköz, pl DataNumen Outlook Repair, így azonnali és időszerű mentést nyerhet az Outlook meghibásodása esetén.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve meggyógyul Sql Server és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com