Hogyan veheti fel automatikusan a törzs első sorát tárgyként, mielőtt tárgy nélkül küldene Outlook e-mailt

Egyes felhasználók azt szeretnék, hogy az Outlook automatikusan az e-mail törzsének első sorát vegye tárgyként, ha tárgy nélküli e-mailt küld. Ebben a cikkben bemutatunk egy módszert a VBA kódon keresztüli megvalósítására.

Több felhasználó gyakran elfelejti megadni a tárgyat e-mail írásakor és elküldésekor. Így általában azt remélik, hogy az Outlook automatikusan kitölti a tárgyat az e-mail törzsének első sorával, ha a kimenő e-mailnek nincs tárgya. A továbbiakban egy egyszerű és praktikus módszert osztunk meg veletek.

Automatikusan vegye a törzs első sorát tárgyként, mielőtt tárgy nélküli e-mailt küldene

1. A legelején indítsa el az Outlook alkalmazást.
2. Ezután kövesse a „A VBA kód futtatása az Outlookban", beléphet a VBA szerkesztőbe.
3. Ezután a VBA-szerkesztőben adja hozzá az „MS Word Object Library” a „Hogyan adjunk hozzá egy Object Lib-etrary Hivatkozás a VBA-ban".
4. Később másolja be az alábbi kódot a „ThisOutlookSession” projektbe.

Private WithEvents objInspectors As Outlook.Inspectors

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail And Inspector.CurrentItem.Subject = "" Then
       Inspector.CurrentItem.Subject = " "
    End If
End Sub

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
    Dim objMailSelection As Word.Selection
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       If Len(Trim(objMail.Subject)) = 0 Then
          If MsgBox("No subject! Whether to take first line as subject?", vbQuestion + vbYesNo) = vbYes Then
             Set objMailDocument = objMail.GetInspector.WordEditor
             Set objMailSelection = objMailDocument.Application.Selection
 
             objMailDocument.Range(0, 0).Select
             objMailSelection.MoveEnd wdLine
 
             'Take first line of body as subject
             objMail.Subject = objMailSelection.Text
          End If
       End If
     End If
End Sub

5. Ezután vigye a kurzort az „Application_Startup” szubrutint, és nyomja meg az „F5” gombot.
6. Végre egy próbát tehetsz.

• Először hozzon létre és írjon egy e-mailt, amelynek tárgya üres.
• Ezután kattintson a „Küldés” gombra.
• Később egy üzenetet kap, amely megkérdezi, hogy a törzs első sorát vegye-e tárgyként.
• Mindaddig, amíg az „Igen” gombot választja, az e-mail törzsének első sora kibontásra kerül, tárgyként kerül felhasználásra, és az e-mail kiküldésre kerül.

Tartsa biztonságban Outlook adatait

Természetesen több jelentős e-mail és egyéb elem is található az Outlookban. Emiatt biztosan nem akar az Outlook adatvesztésével találkozni. Ezután végre kell hajtania néhány műveletet, például rendszeres biztonsági mentést kell készítenie az Outlook adatairól, meg kell tanulnia a beépített javítóeszköz használatát javítsa ki az Outlookot hibákat és egy robusztus külső helyreállítási segédprogram elkészítését. DataNumen Outlook Repair jó választás a magas PST helyreállítási rátája miatt.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sql helyreállítás és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com