Hogyan állítsa be automatikusan az alapértelmezett helyszínt az Ön által szervezett Outlook-találkozókhoz

Lehet, hogy mindig ugyanarra a helyre ütemezi be az értekezleteket, például a cége adott konferenciatermébe. Ha igen, érdemes lehet beállítani a helyiséget az Outlook programban létrehozott összes értekezlet alapértelmezett helyeként. Ez a cikk segít ennek megszerzésében.

Outlook-megbeszélés létrehozásakor meg kell adnia vagy ki kell választania egy helyet. Ellenkező esetben figyelmeztetést kap az üres helyről. Ha megszokta, hogy az általa kezdeményezett értekezleteket egy adott helyen, például ugyanabban a helyiségben tartsa, lehet, hogy a helyiséget szeretné alapértelmezett értekezleti helyként beállítani. Most a következőkben megosztunk veled egy módszert ennek megvalósítására.

Automatikusan állítsa be az Ön által szervezett találkozók alapértelmezett helyszínét

1. Kezdésként indítsa el az Outlook VBA szerkesztőt a „A VBA kód futtatása az Outlookban:.
2. Ezután a VBA-szerkesztőben másolja be a következő kódot a „ThisOutlookSession” projektbe.

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objAppointment As Outlook.AppointmentItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olAppointment Then
       Set objAppointment = Inspector.CurrentItem
    End If
End Sub

Private Sub objAppointment_Open(Cancel As Boolean)
    'If it is a meeting
    If objAppointment.MeetingStatus = olMeeting Then
       'If it is a fresh new meeting
       If objAppointment.Subject = "" Then
          'Enter the specific location
          objAppointment.Location = "Conference Room A"
       End If
    Else
       objAppointment.Location = ""
    End If
End Sub

Private Sub objAppointment_PropertyChange(ByVal Name As String)
    'If you change an appointment into a meeting
    If Name = "MeetingStatus" Then
       If objAppointment.MeetingStatus = olMeeting Then
          'Enter the specific location
          objAppointment.Location = "Conference Room A"
       Else
          objAppointment.Location = ""
       End If
    End If
End Sub

3. Ezután lépjen ki a VBA-szerkesztőből, és indítsa újra az Outlookot a makró aktiválásához.
4. Eddig sikeresen beállította az Ön által szervezett értekezletek alapértelmezett helyszínét.

• Minden alkalommal, amikor új értekezletet hoz létre a „Kezdőlap” fül „Új értekezlet” elemére kattintva, az értekezlet az alapértelmezett hellyel nyílik meg.
• Minden alkalommal, amikor egy találkozót találkozóvá alakít át a „Részvevők meghívása” gombra kattintva, a „Hely” mezőben automatikusan az alapértelmezett helyszín kerül kitöltésre.

Korrupt Outlook adatok mentése

Az Outlookkal kapcsolatos problémák közül a legsúlyosabb az Outlook adatvesztés. Általában először meg kell találni a valódi okokat. Ezután a különböző okok alapján lehet megoldásokat találni. Például, ha a fájl vírussal fertőzött, először a vírusokat kell eltávolítani. Ezután a következőket kell tennie: javítsa ki az Outlookot fájl, akár a beépített javítóeszközzel, akár egy megbízható külső eszközzel, mint pl DataNumen Outlook Repair.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve korrupt sql és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com