Egy adott nyomtató automatikus használata az Outlook e-mailek nyomtatásához

Oszd meg most:

Az Outlook nem konfigurálható úgy, hogy egy adott, nem alapértelmezett nyomtatót használjon az e-mailek nyomtatásához. Ebben a cikkben azonban bemutatunk egy módszert, amellyel elérheti ezt az Outlook VBA segítségével.

A számítógépen egy nyomtatót kell beállítani alapértelmezettként, amely a számítógépen található összes programra érvényes lesz. Ebben az esetben, ha az e-maileket nem alapértelmezett nyomtatón keresztül szeretné kinyomtatni az Outlook programban, minden alkalommal ki kell cserélnie a nyomtatót nyomtatáskor. Eléggé zavaró. Ezért a következőkben megosztunk Önnel egy módot arra, hogy egy adott nyomtatót automatikusan használjon e-mailekhez anélkül, hogy minden alkalommal nyomtatót kellene cserélnie.

Automatikusan használjon meghatározott nyomtatót az Outlook e-mailek nyomtatásához

Automatikusan használjon meghatározott nyomtatót az e-mailek nyomtatásához

  1. Legelőször indítsa el az Outlook alkalmazást.
  2. Ezután az Outlook főablakában nyomja meg az „Alt + F11” billentyűket.
  3. Ezután a megjelenő „Microsoft Visual Basic for Applications” ablakban először engedélyeznie kell a „Microsoft Word objektumtárat”. Ehhez kattintson az „Eszközök” > „Referencia” menüpontra.
  4. Ezután hozzá kell férnie egy üres modulhoz.
  5. Ezt követően másolja ki és illessze be a következő VBA-kódot ebbe a modulba.
Sub PrintEmail()
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim objWordApp As Word.Application
    Dim strTempFolder As String
    Dim strMailDocument As String
    Dim objMailDocument As Word.Document
    Dim strPrinter As String

    Select Case Application.ActiveWindow.Class
           Case olInspector
                Set objItem = ActiveInspector.CurrentItem
           Case olExplorer
                Set objItem = ActiveExplorer.Selection.Item(1)
    End Select
 
    If TypeOf objItem Is MailItem Then
       Set objMail = objItem
 
       Set objWordApp = CreateObject("Word.Application")
       strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
       strMailDocument = strTempFolder & "\" & Format(Now, "yyyymmddssnn") & ".doc"
       objMail.SaveAs strMailDocument, olDoc
 
       Set objMailDocument = objWordApp.Documents.Open(strMailDocument)
       objWordApp.Visible = True
       objMailDocument.Activate
 
       strPrinter = objWordApp.ActivePrinter
       'Change to the name of specific printer
       objWordApp.ActivePrinter = "Specific Printer"
       objWordApp.PrintOut Range:=wdPrintAllDocument, Item:=wdPrintDocumentContent
       objWordApp.ActivePrinter = strPrinter
 
       objMailDocument.Close False
       objWordApp.Quit
       Kill strMailDocument
    End If
End Sub

VBA-kód – Automatikusan használjon meghatározott nyomtatót az Outlook e-mailek nyomtatásához

  1. Ezt követően bezárhatja az aktuális ablakot.
  2. Ezután lépjen a „Fájl” menübe, és kattintson az „Opciók” gombra.
  3. Az „Outlook beállításai” ablakban lépjen a „Gyorselérési eszköztár” fülre, és a szokásos módon adja hozzá az új makrót a Gyorselérési eszköztárhoz.
  4. Végül kipróbálhatja ezt a VBA-projektet.
  • Először válassza ki vagy nyisson meg egy e-mailt, amelyet ki szeretne nyomtatni.
  • Ezután kattintson a makró gombra a Gyorselérési eszköztárban.
  • Az e-mailt az adott nyomtató azonnal kinyomtatja.
  1. Mostantól csak ezt a makrót használhatja az e-mailek adott nyomtatón történő nyomtatásához.

Az Outlook helyreállítása a baleseti korrupció után

Az Outlook-adatok elvesztésének megakadályozása érdekében nagy erőfeszítéseket kell tennie. Például rendszeresen készítsen biztonsági másolatot a PST-fájljáról. Természetesen ajánlott egy külső javítóeszközt beszerezni, például a következőt: DataNumen Outlook Repair. Az tud javítsd ki a PST-t hibákat, és állítsa vissza a maximális Outlook adatot.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve SQL helyreállítása és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com

Oszd meg most:

Hozzászólások lezárva.