Különböző emlékeztető időpontok automatikus beállítása az Outlook találkozóihoz különböző színkategóriákban

Ha az Outlook értekezleteit színkategóriák szerint osztályozza, és különböző színkategóriákba tartozó értekezletekhez eltérő emlékeztető időt szeretne beállítani, tekintse meg ezt a cikket. Itt megtanítjuk megvalósítani az Outlook VBA-val.

Például két csoportra osztja a megbeszéléseket. Az egyik a „Külső” színkategóriába tartozik, mivel a megbeszélés helyszíne túl messze van, a másik pedig a „Helyszíni” színkategóriába, mivel a helyszín itt van. Most azt szeretné, hogy az Outlook automatikusan beállítsa a „külső” megbeszélés emlékeztető időpontját 1 órára a kezdés előtt, a „helyszíni” megbeszélésé pedig 15 percre a kezdés előtt. Ezt a követelményt tekintve a továbbiakban egy gyors módszert mutatunk be.

Különböző emlékeztetők automatikus beállítása a különböző színű kategóriájú találkozókhoz

1. Kezdésként indítsa el az Outlook alkalmazást.
2. Ezután nyomja meg az „Alt + F11” billentyűket a VBA szerkesztő ablakának eléréséhez.
3. Ezután a következő ablakban másolja ki és illessze be az alábbi VBA-kódot a „ThisOutlookSession” projektbe.

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Később az „Application_Startup” alprogramra kell kattintani, és az „F5” billentyűt megnyomni a makró futtatásához.
5. Azóta minden alkalommal, amikor új értekezletet adnak hozzá az alapértelmezett naptárhoz, vagy módosít egy meglévő értekezletet, az Outlook automatikusan ellenőrzi az értekezlet kategóriáit, és automatikusan beállítja a különböző emlékeztető időpontokat.

Az Outlook hibák kiküszöbölése

Időről időre különféle problémák merülhetnek fel az Outlookkal. Ezért rendkívül fontos, hogy a felhasználók megtanulják, hogyan kezeljék az Outlookkal kapcsolatos problémákat. Kezdésként érdemes rendszeresen biztonsági másolatot készíteni az Outlook adatairól. Ezenkívül, ha megengedhető, ajánlott egy hatékony biztonsági mentést tartani. Outlook javítás eszköz a közelben, mint pl DataNumen Outlook Repair. Beolvassa a PST-fájlt, hogy kiderítse az Outlook-problémákat, majd könnyedén megoldja azokat.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sql helyreállítás és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com