A naponta beérkező e-mailek teljes számának automatikus rögzítése egy Excel-fájlban

Ebből a cikkből megtudhatja, hogyan engedélyezheti, hogy az Outlook automatikusan megszámolja, hány e-mailt kapott naponta, és hogyan írja be a számot egy Excel-fájlba.

Sok felhasználónak meg kell számolnia a naponta kapott e-mailek teljes számát. Ezenkívül a jövőbeni kényelmesebb ellenőrzés érdekében sokan hozzászoktak ahhoz, hogy a teljes számot Excel-fájlba rögzítsék. Ebben az esetben természetesen dönthet úgy, hogy minden nap manuálisan számol és rögzít. Ez azonban egy kicsit zavaró. És előfordulhat, hogy néha elfelejti megtenni. Ezért szüksége van egy praktikus módszerre, amellyel az Outlook automatikusan megteheti. Válaszul erre a követelményre, a következőkben megtanítjuk Önnek, hogyan használja a VBA-t annak megvalósításához.

Minden nap automatikusan rögzítse a bejövő e-mailek teljes számát egy Excel-fájlban

1. A legelején indítsa el az Outlook alkalmazást.
2. Ezután nyomja meg az „Alt + F11” billentyűparancsokat az Outlook főablakában.
3. Ezután a felugró VBA-szerkesztő ablakban nyissa meg a „ThisOutlookSession” projektet.
4. Ezt követően másolja ki és illessze be a következő VBA-kódokat ebbe a projektbe.

Private Sub Application_Reminder(ByVal Item As Object)
    If Item.Class = olTask And Item.Subject = "Update Email Count" Then
       Call GetAllInboxFolders
    End If
End Sub

Private Sub GetAllInboxFolders()
    Dim objInboxFolder As Outlook.Folder
    Dim strExcelFile As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nNextEmptyRow As Integer
    Dim lEmailCount As Long
 
    lEmailCount = 0
    Set objInboxFolder = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Call UpdateEmailCount(objInboxFolder, lEmailCount)
 
    ‘Change the path to the Excel file
    strExcelFile = "E:\Email\Email Count.xlsx"
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Open(strExcelFile)
    Set objExcelWorksheet = objExcelWorkbook.Sheets("Sheet1")
 
    nNextEmptyRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
 
    'Add the values into the columns
    objExcelWorksheet.Range("A" & nNextEmptyRow) = nNextEmptyRow - 1
    objExcelWorksheet.Range("B" & nNextEmptyRow) = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
    objExcelWorksheet.Range("C" & nNextEmptyRow) = lEmailCount
 
    'Fit the columns from A to C
    objExcelWorksheet.Columns("A:C").AutoFit
   
    'Save the changes and close the Excel file
    objExcelWorkbook.Close SaveChanges:=True
End Sub

Private Sub UpdateEmailCount(objFolder As Outlook.Folder, ByRef lCurEmailCount As Long)
    Dim objItems As Outlook.Items
    Dim objItem As Object
    Dim objMail As Outlook.MailItem
    Dim strDay As String
    Dim strReceivedDate As String
    Dim lEmailCount As Long
    Dim objSubFolder As Outlook.Folder
 
    Set objItems = objFolder.Items
 
    objItems.SetColumns ("ReceivedTime")
    strDay = Year(Date - 1) & "-" & Month(Date - 1) & "-" & Day(Date - 1)
 
    For Each objItem In objItems
        If objItem.Class = olMail Then
           Set objMail = objItem
           strReceivedDate = Year(objMail.ReceivedTime) & "-" & Month(objMail.ReceivedTime) & "-" & Day(objMail.ReceivedTime)
           If strReceivedDate = strDay Then
              lCurEmailCount = lCurEmailCount + 1
           End If
        End If
    Next
 
    'Process the subfolders in the folder recursively
    If (objFolder.Folders.Count > 0) Then
       For Each objSubFolder In objFolder.Folders
           Call UpdateEmailCount(objSubFolder, lCurEmailCount)
       Next
    End If
End Sub

5. Ezután írja alá ezt a kódot, és módosítsa az Outlook makró beállításait, hogy engedélyezze az aláírt makrókat.
6. Ezt követően napi rendszerességgel létre kell hoznia egy ismétlődő feladatot.

• Először kattintson az „Új feladat” gombra a Feladatok ablaktáblában.
• A felugró Új feladat ablakban kattintson az „Ismétlődés” gombra.
• Ezután a következő párbeszédpanelen válassza ki a „Napi”, „Minden 1 nap(ok)” és a „Nincs befejezési dátum” lehetőséget, és végül nyomja meg az „OK” gombot.
• Később módosítsa a feladat tárgyát és az emlékeztetőt igényei szerint.
• Végül kattintson a „Mentés és bezárás” gombra.

7. Mostantól minden alkalommal, amikor ez a feladat emlékezteti, az Outlook automatikusan megszámolja a tegnap beérkezett e-maileket, majd rögzíti a számot az Excel-fájlba, például a következő képernyőképen:

Menekülés az állandó PST adatvesztés elől

Senki sem hajlandó elfogadni az állandó PST adatvesztést. Az Outlook PST-fájl azonban hajlamos a korrupcióra. Ezért elegendő óvintézkedést kell tennie, például konzisztens és naprakész PST-adatmentés, valamint hatékony PST helyreállítás eszköz a közelben, mint DataNumen Outlook Repair.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sql javítás és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com