2 módszer a különböző kategóriákkal rendelkező Outlook-feladatok listájának nyomtatására különböző oldalakon

Ha különböző színkategóriákat rendelt az Outlook-feladatokhoz, és most szeretné kinyomtatni a különböző kategóriájú feladatok listáit különböző oldalakon, tekintse meg ezt a cikket. Itt megosztunk veled 2 módszert, hogy megszerezd.

A feladatok osztályozása és megfelelő kezelése érdekében talán színkategóriákat alkalmazott a feladatokra. Most, ha szeretné kinyomtatni a feladatok listáját különböző kategóriákkal különböző oldalakon, kérjük, olvasson tovább. A következőkben 2 módot mutatunk be ennek megszerzéséhez.

1. módszer: Feladatlisták manuális nyomtatása egyenként

1. Először az Outlookban nyissa meg a „Feladatok” panelt.
2. Ezután nyisson meg egy Feladat mappát.
3. Ezután nyomja meg a „Ctrl + E” billentyűket a „Keresés” szalag aktiválásához.
4. Ezután a „Keresés” fülön kattintson a „Kategorizálás” gombra.
5. A legördülő listából válasszon színkategóriát.
6. Ekkor csak a kiválasztott kategóriájú feladatok maradnak a listában.
7. Most lépjen a „Fájl” > „Nyomtatás” menüpontra a feladatlista kinyomtatásához.
8. Ezt követően ugyanígy kézzel egyenként nyomtassa ki a feladatlistákat a többi színkategóriával.

2. módszer: A feladatlisták kötegelt nyomtatása VBA segítségével

1. A legelején indítsa el a VBA-szerkesztőt a „A VBA kód futtatása az Outlookban".
2. Ezután adja hozzá az „MS Excel Object Library” hivatkozást a „Objektumkönyvtár-hivatkozás hozzáadása VBA-ban".
3. Ezután másolja be a következő VBA-kódot egy modulba.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Ezután nyomja meg az „F5” gombot a makró azonnali futtatásához.
5. Amikor a makró befejeződik, a különböző kategóriájú feladatok listái különböző oldalakon lesznek kinyomtatva, ahogy az a következő képernyőképen látható.

Szerezzen vissza értékes adatokat a veszélyeztetett PST-fájlból

Ha nem érhető el PST-fájl, akkor a következő lépés kétségtelenül az PST javítás. Ebben az esetben először kipróbálhatja a postafiókjavító eszközt. Ha nem sikerül, próbálkozhat egy másik külső eszközzel, mint pl DataNumen Outlook Repair. Gyorsan képes helyreállítani a PST-adatokat.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve mdf helyreállítása és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com