2 gyors módszer az összes továbbított e-mail megkeresésére az Outlookban

Ha gyorsan meg szeretné találni az összes olyan e-mailt, amelyet másoknak továbbított az Outlook programban, olvassa el ezt a cikket. Itt 2 hatékony módszert osztunk meg veled.

Mint mindannyian tudjuk, a továbbított e-mailek ikonjában egy kék jobbra mutató nyíl található. Könnyen felismerhető a rengeteg e-mail között. Időnként érdemes ellenőrizni az összes továbbított fájlt az Outlookban. Ebben az esetben a kényelem kedvéért meg kell találnia és ugyanott kell összegyűjtenie őket. Az Outlook nem biztosít közvetlen feltételeket a felhasználók számára az átirányított e-mailek kereséséhez. A következő 2 módszerrel azonban továbbra is könnyen elérheti.

1. módszer: Keressen továbbított e-maileket egy mappában

1. Kezdésként nyisson meg egy levelező mappát, például a „Beérkezett üzenetek” mappát.
2. Ezután lépjen a „Nézet” fülre, és kattintson a „Nézetbeállítások” gombra.
3. Ezután a felugró párbeszédpanelen kattintson a „Szűrés” gombra.
4. Ezt követően az új párbeszédpanelen lépjen az „SQL” fülre.
5. Ezt követően jelölje be a „Ezen feltételek közvetlen szerkesztése” lehetőséget. Az összes többi lap nem lesz elérhető” alul.
6. Később helyezze a kurzort a fenti mezőbe, és másolja be a következő feltételeket.

http://schemas.microsoft.com/mapi/proptag/0x10810003 = 104

7. Végül kattintson egy sor „OK” gombra a nézetbeállítások mentéséhez.
8. Amikor visszatér a mappába, azt tapasztalja, hogy csak a továbbított e-mailek vannak ott, mint az alábbi ábra.

2. módszer: Keressen továbbított e-maileket az összes mappában

1. Kezdésként indítsa el az Outlook VBA szerkesztőt az „Alt + F11” billentyűkombinációval.
2. Ezután helyezze be a következő VBA-kódot egy modulba.

Sub GetEmailForwardedStatus()
    Dim objPSTFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Process all folders in your default Outlook file
    Set objPSTFolders = Application.Session.GetDefaultFolder(olFolderInbox).Parent.Folders
 
    For Each objFolder In objPSTFolders
        If objFolder.DefaultItemType = olMailItem Then
           Call ProcessFolders(objFolder)
        End If
    Next
End Sub

Sub ProcessFolders(ByVal objFolder As Outlook.Folder)
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim objForwardedProperty As Outlook.UserProperty
    Dim strForwardedStatus As String
    Dim objSubFolder As Outlook.Folder
 
    'Get the forwarded status of all mails
    For i = objFolder.Items.Count To 1 Step -1
        If TypeOf objFolder.Items(i) Is MailItem Then
           Set objMail = objFolder.Items(i)
 
           Set objForwardedProperty = objMail.UserProperties.Find("Forwarded", True)
           If objForwardedProperty Is Nothing Then
              Set objForwardedProperty = objMail.UserProperties.Add("Forwarded", olText, True)
           End If
 
           strForwardedStatus = objMail.PropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x10810003")
           If strForwardedStatus = 104 Then
              objForwardedProperty.Value = "Yes"
           Else
              objForwardedProperty.Value = "No"
           End If
 
           objMail.Save
        End If
    Next
 
    'Process subfolders recursively
    If objFolder.Folders.Count > 0 Then
       For Each objSubFolder In objFolder.Folders
           If objSubFolder.DefaultItemType = olMailItem Then
              Call ProcessFolders(objSubFolder)
           End If
       Next
    End If
End Sub

3. Ezután kattintson az első szubrutinra, és nyomja meg az „F5” billentyűt.
4. Ezt követően lépjen ki a VBA szerkesztőből.
5. Ezután a levelező mappalistában kattintson jobb gombbal a „Keresési mappák” elemre, és válassza az „Új keresési mappa” lehetőséget.
6. A felugró párbeszédpanelen válassza az „Egyéni keresési mappa létrehozása” lehetőséget, majd kattintson a „Kiválasztás” gombra.
7. Ezután az „Egyéni keresési mappa” párbeszédpanelen írja be a „Továbbított e-mailek” elemet a „Név” mezőbe, és kattintson a „Feltételek” gombra.
8. Később a legutóbbi párbeszédpanelen váltson a „Speciális” fülre, és adja hozzá a következő szűrőt.

• „Továbbítva” > „(pontosan)” > „Igen”

9. Végül kattintson néhány „OK” gombra egy ilyen egyéni keresési mappa létrehozásához.
10. Sikeres létrehozása után, ebben a keresési mappában, az alapértelmezett Outlook adatfájlban lévő összes továbbított e-mailt itt gyűjtöttük össze, az alábbi képen látható módon.

Menekülés az Outlook adatvesztés elől

Minden Outlook rendszeres felhasználó számára az Outlook adatvesztése biztosan elfogadhatatlan. Ezért elengedhetetlen néhány hatékony intézkedés végrehajtása, beleértve a rendszeres adatmentést a PST-fájlokról, a beérkező levelek javítóeszközének használatának megtanulását, valamint egy megbízható és hatékony PST javítás eszköz, pl DataNumen Outlook Repair. Ezekkel az előkészületekkel, még ha a PST fájl megsérült is, könnyedén visszaállíthatja őket.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve sérült sql és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com