2 módszer az e-mailek feladónkénti gyors megszámlálására az Outlookban

Ha feladó szerint szeretné számolni az e-maileket, tekintse meg ezt a cikket. Itt 2 gyors megközelítést mutatunk be Önnek.

Annak érdekében, hogy megtudja, ki a legaktívabb feladó, érdemes lehet feladó szerint megszámolni az e-maileket. Bár az Outlook nem biztosít erre közvetlen funkciót, mégis kereshet néhány kerülő megoldást, például az alábbi 1. módszert. Ha úgy gondolja, hogy az 1. módszer túl unalmas, választhatja a 2. módszert. Ez sokkal hatékonyabb, mivel VBA-t használ az e-mailek gyors feladó szerinti megszámolásához, és az adatok Excelbe exportálásához. Most olvassa el részletesen a két módszert. Itt a Beérkezett üzenetek mappájában lévő e-maileket vesszük példaként.

1. módszer: Számlások lekérése, miután az elemeket csoportosította a „From” mező szerint

1. Kezdésként indítsa el az Outlook alkalmazást.
2. Ezután nyissa meg a beérkező levelek mappát.
3. Ezután váltson a „Nézet” fülre.
4. Ezt követően az „Elrendezés” csoportban válassza a „From” lehetőséget.
5. Egyszerre az összes beérkezett üzenet különböző csoportokba került a különböző feladók szerint.
6. Most egy adott feladótól származó tételek megszámlálásához válassza ki a kapcsolódó csoport összes elemét, és nyomja meg az „Enter” gombot. A felugró figyelmeztetésben láthatja a számot.

Ez azt jelenti, hogy meglehetősen egyszerű, de a tételszámok valójában más típusú elemeket is tartalmaznak, mint például a találkozók meghívásai, a feladatkérések és a nyugták, nem csak az e-mailek száma. Így, ha csak az e-maileket szeretné számolni, használhatja a következő módszert.

2. módszer: Az e-mailek számlálása feladó szerint az Outlook VBA segítségével

1. Kezdésként nyomja meg az „Alt + F11” billentyűkombinációt az Outlookban.
2. Ezután engedélyezze az „MS Excel Object Library”-t a „Objektumkönyvtár-hivatkozás hozzáadása VBA-ban".
3. Ezután másolja be az alábbi kódot egy nem használt modulba.

Sub CountInboxEmailsbySender()
    Dim objDictionary As Object
    Dim objInbox As Outlook.Folder
    Dim i As Long
    Dim objMail As Outlook.MailItem
    Dim strSender As String
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varSenders As Variant
    Dim varItemCounts As Variant
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
 
    For i = objInbox.Items.Count To 1 Step -1
        If objInbox.Items(i).Class = olMail Then
           Set objMail = objInbox.Items(i)
           strSender = objMail.SenderEmailAddress
 
           If objDictionary.Exists(strSender) Then
              objDictionary.Item(strSender) = objDictionary.Item(strSender) + 1
           Else
              objDictionary.Add strSender, 1
           End If
        End If
    Next

    Set objExcelApp = CreateObject("Excel.Application")
    objExcelApp.Visible = True
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Sender"
         .Cells(1, 2) = "Count"
    End With
 
    varSenders = objDictionary.Keys
    varItemCounts = objDictionary.Items
 
    For i = LBound(varSenders) To UBound(varSenders)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
        With objExcelWorksheet
             .Cells(nLastRow, 1) = varSenders(i)
             .Cells(nLastRow, 2) = varItemCounts(i)
        End With
    Next
 
    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

3. Ezután nyomja meg az „F5” gombot.
4. Amikor a makró befejeződik, egy új Excel-fájl jelenik meg.
5. Amint láthatja, tartalmazza a különböző feladóktól érkező beérkező levelek számát.

Távolítsa el a bosszantó Outlook-problémákat

Lehet, hogy valaha is sok probléma volt az Outlookban. A hatékony kezelés érdekében sokoldalú és hatalmas útra vágyhat. Valójában azonban nem létezik ilyen módszer. Amit tehet, az az, hogy vigyázzon saját műveleteivel az Outlookban, és rendszeresen készítsen biztonsági másolatot. Természetesen, ha lehetséges, javasoljuk, hogy tartson kéznél egy tapasztalt javítóeszközt, mint pl DataNumen Outlook Repair. Különféle PST-problémákat javíthat és javíthat korrupt PST fájl, mint egy szellő.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve meggyógyul Sql Server és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com