2 egyszerű módszer Outlook-feladat gyors létrehozására Excel-munkafüzethez

Néhány felhasználó szívesen létrehoz egy Outlook-feladatot egy Excel-munkafüzethez. Ezért ebben a cikkben 2 egyszerű megközelítést mutatunk be ennek eléréséhez.

Időnként érdemes lehet létrehozni egy Outlook-feladatot Excel-fájlból nyomon követés vagy egyéb okok miatt. Valójában a Microsoft Excel tartalmazza a „Microsoft Outlook-feladat létrehozása” natív funkciót, például a következőkben bemutatott 1. módszert. De csak az Excel-munkafüzetet csatolja egy Outlook-feladathoz. Ha az összes munkalap teljes tartalmát gyorsan át szeretné másolni egy Outlook-feladat törzsébe, használhatja helyette a 2. módszert. Most olvassa el, hogy részletesen megismerje a 2 eszközt.

1. módszer: Használja a „Microsoft Outlook Task létrehozása” parancsot az MS Excelben

1. Először nyissa meg az adott Excel-munkafüzetet.
2. Ezután kattintson a lefelé mutató nyíl gombra a Gyorselérési eszköztáron.
3. Ezután válassza a „További parancsok” lehetőséget a legördülő listából.
4. Később az új „Excel-beállítások” ablak „Gyorselérési eszköztár” lapján adja hozzá a „Microsoft Outlook-feladat létrehozása” parancsot a Gyorselérési eszköztárhoz.

• Először válassza ki a „Parancsok nincsenek a szalagon” elemet a „Parancsok kiválasztása innen” listából.
• Ezután keresse meg és helyezze el a „Microsoft Outlook feladat létrehozása” parancsot.
• Ezután kattintson a középen található „Hozzáadás >>” gombra.
• Végül nyomja meg az „OK” gombot.

5. Végül, miután visszatért az Excel-munkafüzethez, kattintson az új gombra a Gyorselérési eszköztárban.
6. Egyszerre megjelenik egy új Outlook-feladat, amely az aktuális Excel-munkafüzethez lett csatolva, mint a következő képernyőkép.

2. módszer: Másolja az Excel-munkafüzetet egy Outlook-feladat törzsébe VBA-kóddal

1. Először nyissa meg az Excel forrásfájlt.
2. Ezután nyomja meg az „Alt + F11” gombot az Excel VBA szerkesztő elindításához.
3. Ezt követően engedélyezze a „Microsoft Outlook objektumtárat”, amelyről a „” részben olvashat bővebben.Objektumkönyvtár-hivatkozás hozzáadása VBA-ban".
4. Ezután helyezze el az alábbi VBA-kódot egy modulba vagy „ThisWorkbook” projektbe.

Sub CreateOutlookTaskforExcelWorkbook()
    Dim objOutlookApp As Outlook.Application
    Dim objTask As Outlook.TaskItem
    Dim objWorksheet As Excel.Worksheet
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempFolder As String
    Dim strHTMLFile As String
    Dim objHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objTempMail As Outlook.MailItem
 
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objTask = objOutlookApp.CreateItem(oltaskitem)
    objTask.Subject = ActiveWorkbook.Name
    objTask.Display
 
    For Each objWorksheet In ActiveWorkbook.Sheets
        objWorksheet.UsedRange.Copy
 
        Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
        Set objTempWorksheet = objTempWorkbook.Sheets(1)
        With objTempWorksheet.Cells(1)
             .PasteSpecial xlPasteValues
             .PasteSpecial xlPasteColumnWidths
             .PasteSpecial xlPasteFormats
        End With
 
        strTempFolder = CStr(Environ("USERPROFILE")) & "\AppData\Local\Temp"
        strHTMLFile = strTempFolder & "\Temp" & Format(Now, "yyyymmddhhmmss") & ".htm"
        Set objHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
        objHTMLFile.Publish (True)

        Set objTempMail = objOutlookApp.CreateItem(olMailItem)
 
        Set objFileSystem = CreateObject("Scripting.FileSystemObject")
        Set objTextStream = objFileSystem.OpenTextFile(strHTMLFile)
        objTempMail.HTMLBody = objTextStream.ReadAll
        objTempMail.Display
 
        objTask.Body = objTask.Body & vbCr & "-----------------------" & vbCr & objTempMail.Body

        objTextStream.Close
        objTempWorkbook.Close False
        Kill strHTMLFile
        objTempMail.Close olDiscard
    Next
End Sub

5. Végül nyomja meg az „F5” billentyűket.
6. Amikor a makró befejeződik, egy Outlook-feladatot kap, amely az Excel-munkafüzet tartalmát tartalmazza a törzsben, az alábbi képernyőképen látható módon.

Állítsa vissza az Outlook-adatokat a biztonsági másolatokból

Erősen ajánlott rendszeres időközönként biztonsági másolatot készíteni a számítógép adatairól, természetesen az Outlook adatfájlokról is. Ily módon nem kell aggódnia az Outlook adatvesztés miatt. Még akkor is, ha az Outlook-fájl megsérül, könnyedén lekérheti az adatokat a biztonsági másolatokból. De feltéve, hogy nem készített biztonsági másolatot az adatokról, ilyen esetekben meg kell kísérelnie a PST helyreállítást egy profi javító segédprogrammal, mint pl. DataNumen Outlook Repair. Az tud visszaállítani a PST-t izzadságot nem törve.

Szerző Bevezetés:

Shirley Zhang adat-helyreállítási szakértő DataNumen, Inc., amely világelső az adat-helyreállítási technológiák területén, beleértve javítás mdf és outlook javítószoftver termékek. További információért látogasson el www.datanumen.com