Comment exporter rapidement un dossier Outlook avec tous les sous-dossiers et éléments vers un dossier Windows

Parfois, vous souhaiterez peut-être exporter par lots un dossier Outlook avec tous les sous-dossiers et éléments vers un dossier Windows. Cet article vous apprendra une telle méthode qui applique Outlook VBA.

Lorsque vous souhaitez exporter un dossier Outlook vers un lecteur local avec tous les éléments dans la même structure de dossiers, si vous choisissez d'enregistrer et d'exporter manuellement, cela vous prendra beaucoup de temps. Ainsi, pourquoi ne recourez-vous pas à d'autres moyens, tels que des outils d'exportation ou des codes VBA ? Ici, nous allons vous dévoiler un tel morceau de code VBA. Il vous permettra de le réaliser comme un jeu d'enfant.

Exporter tous les sous-dossiers et éléments d'un dossier Outlook vers un dossier Windows

1. Dès le départ, lancez votre programme Outlook.
2. Ensuite, dans la fenêtre principale d'Outlook, appuyez sur les raccourcis clavier "Alt + F11".
3. Par la suite, la fenêtre "Microsoft Visual Basic pour Applications" apparaîtra.
4. Ensuite, vous devez ouvrir un module vierge et y copier les codes VBA suivants.

Private objFileSystem As Object
 
Private Sub ExportFolderWithAllItems()
    Dim objFolder As Outlook.Folder
    Dim strPath As String
 
    'Specify the root local folder
    'Change it as per your needs
    strPath = "E:\Outlook\"
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
 
    'Select a Outlook PST file or Outlook folder
    Set objFolder = Outlook.Application.Session.PickFolder
 
    Call ProcessFolders(objFolder, strPath)
 
    MsgBox "Complete", vbExclamation
End Sub
 
Private Sub ProcessFolders(objCurrentFolder As Outlook.Folder, strCurrentPath As String)
    Dim objItem As Object
    Dim strSubject, strFileName, strFilePath As String
    Dim objSubfolder As Outlook.Folder
 
    'Create the local folder based on the Outlook folder
    strCurrentPath = strCurrentPath & objCurrentFolder.Name
    objFileSystem.CreateFolder strCurrentPath
 
    For Each objItem In objCurrentFolder.Items
 
        strSubject = objItem.Subject
 
        'Remove unsupported characters in the subject
        strSubject = Replace(strSubject, "/", " ")
        strSubject = Replace(strSubject, "\", " ")
        strSubject = Replace(strSubject, ":", "")
        strSubject = Replace(strSubject, "?", " ")
        strSubject = Replace(strSubject, Chr(34), " ")

        strFileName = strSubject & ".msg"
 
        i = 0
        Do Until False
           strFilePath = strCurrentPath & "\" & strFileName
           'Check if there exist a file in the same name
           If objFileSystem.FileExists(strFilePath) Then
              'Add a sequence order to the file name
              i = i + 1
              strFileName = strSubject & " (" & i & ").msg"
           Else
              Exit Do
          End If
        Loop
 
        'Save as MSG file
        objItem.SaveAs strFilePath, olMSG
    Next
 
    'Process subfolders recursively
    If objCurrentFolder.folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.folders
           Call ProcessFolders(objSubfolder, strCurrentPath & "\")
       Next
    End If
End Sub

5. Après cela, vous devez vous assurer que votre Outlook autorise les macros dans les paramètres de macro.
6. Finalement, vous pouvez essayer.

• Tout d'abord, revenons à la nouvelle fenêtre de macro.
• Cliquez ensuite sur la sous-routine "ExportFolderWithAllItems".
• Appuyez ensuite sur la touche F5 pour exécuter cette macro.
• Après cela, vous devez sélectionner un dossier spécifique.
• Enfin, lorsque vous recevez un message disant "Terminé", vous pouvez accéder au dossier local prédéfini. Vous constaterez que tous les éléments ont été enregistrés dans la même structure de dossiers.

Empêcher la perte de données due aux plantages d'Outlook

Vous avez peut-être déjà rencontré de nombreux plantages d'Outlook. La plupart du temps, après un redémarrage, Outlook fonctionne à nouveau normalement. Cependant, il arrive aussi que votre fichier PST soit corrompu. Dans ce cas, vous tenterez de récupérer vos données PST, par exemple en utilisant un outil spécialisé comme [nom de l'outil/du logiciel]. DataNumen Outlook Repair. Il est capable de réparer Outlook erreurs et extraire les données du fichier PST compromis sans transpirer.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris SQL Server réparation et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com