Comment exporter rapidement un e-mail Outlook en tant que fichier image

Certains utilisateurs souhaitent exporter un e-mail Outlook sous forme de fichier image, tel qu'un fichier jpg. Par conséquent, dans cet article, nous vous présenterons comment l'obtenir via le code Outlook VBA.

Vous devez avoir appris diverses astuces pour exporter un e-mail sous forme de fichier texte, de document Word, etc. Alors, que diriez-vous d'exporter un e-mail sous forme d'image comme un fichier JPG ? Apparemment, Outlook n'a pas cette fonction. Mais, ci-après, nous partagerons un moyen rapide avec vous.

Exporter rapidement un e-mail Outlook en tant que fichier image

1. Pour commencer, lancez votre application Outlook.
2. Ensuite, dans la fenêtre principale d'Outlook, accédez à l'éditeur VBA conformément à l'article - "Comment exécuter le code VBA dans votre Outlook ».
3. Ensuite, activez « Bibliothèque d’objets MS Word » et « MS ». PowerPoint Bibliothèque d'objets » en se référant à l'article – «Comment ajouter une référence à une bibliothèque d'objets en VBA ».
4. Ensuite, copiez et collez le code VBA suivant dans un module vide.

Sub ExportEmailAsImage()
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim strWordDocument As String
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim objDocumentRange As Word.Range
    Dim objPowerPointApp As PowerPoint.Application
    Dim objPresentation As PowerPoint.Presentation
    Dim objShape As PowerPoint.Shape
 
    On Error Resume Next
    'Export the email as Word document
    Set objMail = Outlook.Application.ActiveExplorer.Selection(1)
    strFileName = Replace(objMail.Subject, "/", " ")
    strFileName = Replace(strFileName, "\", " ")
    strFileName = Replace(strFileName, ":", "")
    strFileName = Replace(strFileName, "?", " ")
    strFileName = Replace(strFileName, Chr(34), " ")
    strWordDocument = Environ("Temp") & "\" & strFileName & ".doc"
 
    objMail.SaveAs strWordDocument, olDoc

    Set objWordApp = CreateObject("Word.Application")
    Set objWordDocument = objWordApp.Documents.Open(strWordDocument)
    objWordApp.Visible = True
 
    objWordApp.Selection.Find.ClearFormatting
    objWordApp.Selection.Find.Replacement.ClearFormatting
 
    With objWordApp.Selection.Find
        .Text = "^p^p"
        .Replacement.Text = "^p"
        .Wrap = wdFindContinue
    End With
 
    'Insert the document into a PowerPoint Presentation slide as an object
    objWordApp.Selection.Find.Execute Replace:=wdReplaceAll
    Set objDocumentRange = objWordDocument.Range()
    objDocumentRange.Font.Name = "Calibri"
    objDocumentRange.Font.Size = 10
    objWordDocument.Close True
    objWordApp.Quit
 
    Set objPowerPointApp = CreateObject("PowerPoint.Application")
    Set objPresentation = objPowerPointApp.Presentations.Add
    objPowerPointApp.Visible = msoTrue
 
    With objPresentation
        .PageSetup.SlideHeight = 792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
 
    'Export the slide
    With objPresentation.Slides(1)
         Set objShape = .Shapes.AddOLEObject(0, 0, 612, 792, , strWordDocument)
        .Export "E:\Email_" & strFileName & ".jpg", "JPG"
    End With
 
    objPresentation.Saved = msoTrue
    objPresentation.Close
    objPowerPointApp.Quit
End Sub

5. Après cela, vous devez ajouter la macro à la barre d'outils d'accès rapide.
6. Par la suite, vous pouvez fermer l'éditeur VBA.
7. Plus tard, sélectionnez un e-mail et appuyez sur le bouton macro dans la barre d'outils d'accès rapide.
8. Une fois la macro terminée, vous pouvez accéder au dossier local prédéfini pour rechercher le fichier image exporté à partir de cet e-mail.

Récupérer les données Outlook à partir d'un fichier corrompu

Il peut être très frustrant de voir son fichier Outlook gravement endommagé. Dans ce cas, vous devrez extraire les données Outlook du fichier compromis. Certains utilisateurs ont tendance à utiliser l'outil de réparation de la boîte de réception. Cependant, la plupart du temps, cela s'avère inefficace. Il est donc préférable de disposer d'une solution de secours performante et fiable. Correction PST outil, tel que DataNumen Outlook Repair. Il peut analyser le fichier corrompu et récupérer un maximum de données sans aucun problème.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris correctif mdf et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com