Comment copier rapidement la structure des dossiers d'un fichier Outlook PST à un autre via VBA

Si vous souhaitez copier la structure des dossiers d'un fichier Outlook PST à un autre, vous pouvez utiliser la méthode présentée dans cet article, qui vous apprendra à utiliser VBA pour l'obtenir en une seule fois.

Peut-être, afin de mieux gérer vos e-mails, avez-vous créé plusieurs dossiers personnalisés dans votre fichier Outlook principal. Ainsi, lors de la création d'un nouveau fichier Outlook PST, vous souhaiterez peut-être appliquer la même structure de dossiers. En fait, dans mon article précédent - "2 étapes pour conserver l'arborescence des dossiers actuelle dans un nouveau fichier Outlook", vous pouvez apprendre une méthode traditionnelle, qui utilise la fonction " Archiver " pour y parvenir. Néanmoins, en réalité, cela reste un peu fastidieux. Par rapport à cela, l'utilisation de codes VBA pour l'obtenir sera beaucoup plus rapide. Par conséquent, dans ce qui suit, nous vous indiquerons les étapes et les codes élaborés.

Copier la structure des dossiers d'un fichier Outlook PST à un autre

1. Dès le départ, lancez votre programme Outlook.
2. Ensuite, dans la fenêtre Outlook, appuyez sur les touches "Alt + F11".
3. Ensuite, vous entrerez dans la fenêtre de l'éditeur Outlook VBA.
4. Ensuite, copiez et collez les codes VBA suivants dans un nouveau module.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. Après cela, réglez votre niveau de sécurité des macros sur faible.
6. Plus tard, revenez à la fenêtre de l'éditeur VBA et appuyez sur la touche "F5" pour exécuter la macro.
7. Enfin, une fois que la macro a fini de fonctionner, vous recevrez un message indiquant "Terminé !".
8. À ce stade, vous pouvez accéder au volet de navigation du courrier. Vous verrez un nouveau fichier de données Outlook qui se trouve dans la même structure de dossiers que le fichier PST source, comme l'image ci-dessous :

Faire face aux problèmes PST décourageants

Comme Outlook PST est sujet aux erreurs, beaucoup d'entre vous doivent avoir déjà rencontré divers problèmes dans Outlook. Face à eux, vous pouvez d'abord utiliser l'outil de réparation de la boîte de réception Outlook pour essayer. En cas d'échec, vous pouvez alors appliquer un outil tiers plus puissant, tel que DataNumen Outlook Repair, Qui peut réparer Outlook Les erreurs PST comme un jeu d'enfant.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris SQL Server fixer et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com