Comment joindre rapidement les pages spécifiques d'un document Word à un e-mail Outlook

MS Word a une fonctionnalité directe permettant aux utilisateurs d'envoyer le document Word actuel en tant que pièce jointe à un e-mail. Mais parfois, vous pouvez seulement espérer joindre les pages spécifiques d'un document Word à un e-mail Outlook. Maintenant, cet article va vous partager une méthode.

Pour envoyer un document Word entier en pièce jointe dans un e-mail dans l'application MS Word, vous pouvez simplement aller dans le menu "Fichier" et passer à l'onglet "Enregistrer et envoyer", sous lequel vous pouvez trouver un bouton "Envoyer en pièce jointe". Pourtant, parfois, ce que vous souhaitez envoyer peut être uniquement des pages spécifiques du document. Dans cette situation, vous pouvez utiliser la méthode présentée dans ce qui suit pour l'accomplir.

Joindre les pages spécifiques d'un document Word à un e-mail

1. Tout d'abord, vous devez ouvrir le document Word source dont vous souhaitez envoyer les pages spécifiques par courrier électronique.
2. Ensuite, après être entré dans la fenêtre MS Word, vous devez appuyer sur les touches "Alt + F11".
3. Ensuite, vous aurez accès à l'éditeur VBA dans MS Word.
4. Ensuite, vous devez activer la « Bibliothèque d’objets Microsoft Outlook ». Pour ce faire, cliquez sur « Outils » > « Références ».
5. Ensuite, vous devez copier le code VBA suivant dans un module qui n'est pas utilisé.

Sub AttachSpecificPagesToOutlookEmail()
    Dim strDocumentName As String
    Dim objSelectedPages As Word.Range
    Dim objTempDocument As Word.Document
    Dim objTempRange As Word.Range
    Dim i As Long
    Dim strTempDocument As String
    Dim objOutlookApp As Outlook.Application
    Dim objMail As Outlook.MailItem
 
    strDocumentName = Left(ActiveDocument.Name, InStr(ActiveDocument.Name, ".") - 1)
 
    'Copy the contents from Page 2 to 4
    'You can change the page as per your own needs
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=2
    Set objSelectedPages = Selection.Range
    Selection.GoTo What:=wdGoToPage, Which:=wdGoToAbsolute, Count:=4
    objSelectedPages.End = Selection.Bookmarks("\Page").Range.End
    objSelectedPages.Select
    objSelectedPages.Copy
 
    'Paste the copied contents into a new Word Document
    Set objTempDocument = Word.Application.Documents.Add
    objTempDocument.Activate
    Set objTempRange = objTempDocument.Range(0, 0)
    objTempRange.PasteAndFormat (wdFormatOriginalFormatting)

    For i = objTempDocument.Paragraphs.Count To 1 Step -1
        If Len(objTempDocument.Paragraphs(i).Range) = 1 Then
           objTempDocument.Paragraphs(i).Range.Delete
        Else
           Exit For
        End If
    Next i
 
    'Save this document
    strTempDocument = "E:\" & strDocumentName & " (Excerpt).doc"
    objTempDocument.SaveAs2 strTempDocument, wdFormatDocument
 
    'Attach the new document to a new Outlook email
    On Error Resume Next
    Set objOutlookApp = GetObject(, "Outlook.Application")
    If objOutlookApp Is Nothing Then
       Set objOutlookApp = CreateObject("Outlook.Application")
    End If
 
    Set objMail = objOutlookApp.CreateItem(olMailItem)
    objMail.Attachments.Add (strTempDocument)
    objMail.Display
 
    objTempDocument.Close False
    Kill strTempDocument
End Sub

6. Enfin, vous pouvez exécuter cette macro. Appuyez simplement sur la touche F5 ou appuyez sur l'icône "Exécuter" dans la barre d'outils.
7. Une fois la macro terminée, un nouvel e-mail Outlook s'affichera, qui est joint avec un extrait du document Word source, comme la capture d'écran suivante :

Extraire un maximum de données d'un fichier Outlook corrompu

Si vous utilisez Outlook depuis des décennies, vous avez peut-être été confronté à divers problèmes Outlook, notamment des messages d'erreur internes contextuels, des plantages soudains ainsi que de graves dommages aux fichiers. En raison du fait que le Scanpst, outil de réparation intégré, ne peut traiter que les petits problèmes, vous feriez mieux de garder à portée de main un puissant outil de réparation externe, par exemple DataNumen Outlook Repair. Il est capable d'extraire un maximum de données du fichier de données Outlook endommagé.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris correction sql et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com