Comment définir une heure de rappel par défaut différente pour différents types d'éléments signalés dans votre Outlook

Par défaut, Outlook utilisera automatiquement l'heure de rappel par défaut des tâches pour tous les types d'éléments marqués. Cependant, si vous souhaitez utiliser une heure de rappel différente pour les éléments signalés en fonction du type d'élément, vous pouvez vous référer à la méthode présentée dans cet article.

Outlook vous permet de définir une heure de rappel par défaut pour tous les éléments marqués, quel que soit le type d'élément. Vous pouvez aller dans le menu "Fichier" et cliquer sur "Options". Ensuite, dans la fenêtre "Options Outlook", vous pouvez voir l'option "Heure de rappel par défaut" sur l'onglet "Tâches", comme indiqué dans la capture d'écran suivante.

Néanmoins, la plupart des utilisateurs souhaitent utiliser des horaires de rappel différents selon le type d'éléments signalés, par exemple « 9h00 » pour les courriels signalés et « 17h30 » pour les contacts signalés. Nous allons maintenant nous concentrer sur cet exemple pour présenter une méthode.

Définir une heure de rappel par défaut différente pour différents types d'éléments signalés

1. Pour commencer, lancez l'application Outlook.
2. Ensuite, accédez à l'éditeur Outlook VBA en faisant référence à "Comment exécuter le code VBA dans votre Outlook" .
3. Dans la fenêtre suivante "Microsoft Visual Basic pour Applications", copiez le code suivant dans le projet "ThisOutlookSession".

Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objMail As Outlook.MailItem
Public WithEvents objContact As Outlook.ContactItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
    ElseIf TypeOf objExplorer.Selection.Item(1) Is ContactItem Then
       Set objContact = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
    ElseIf Inspector.CurrentItem.Class = olContact Then
       Set objContact = Inspector.CurrentItem
    End If
End Sub

Private Sub objMail_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objMail.IsMarkedAsTask = True Then
          If objMail.TaskDueDate <> "1/1/4501" Then
             With objMail
                  .ReminderSet = True
                  'Change the reminder time for flagged emails
                  .ReminderTime = objMail.TaskDueDate & " 10:00"
                  .Save
             End With
          End If
       End If
    End If
End Sub

Private Sub objContact_PropertyChange(ByVal Name As String)
    If Name = "ToDoTaskOrdinal" Then
       If objContact.IsMarkedAsTask = True Then
          If objContact.TaskDueDate <> "1/1/4501" Then
             With objContact
                  .ReminderSet = True
                  'Change the reminder time for flagged contacts
                  .ReminderTime = objContact.TaskDueDate & " 17:30"
                  .Save
             End With
          End If
       End If
    End If
End Sub

4. Ensuite, redémarrez Outlook pour activer cette macro.
5. À partir de maintenant, chaque fois que vous signalerez un e-mail, l'heure de rappel sera définie sur "10h00" à la date d'échéance du signalement.
6. Et lorsque vous signalez un contact, l'heure de rappel sera définie sur "17h30" à la date d'échéance du signalement.

Traitez les problèmes d'Outlook avec souplesse

Vous pouvez rencontrer toutes sortes de problèmes avec Outlook. Il est donc important d'apprendre à les résoudre à l'avance. Par exemple, si Outlook redémarre fréquemment, vous devrez peut-être réparer Office ou désactiver les compléments tiers. Si votre fichier PST Outlook est compromis, vous pouvez commencer par essayer… outil de réparation de boîte de réception. En cas d'échec, vous pouvez continuer à recourir à un puissant outil externe, comme DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris récupération mdf et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com