Comment créer rapidement un groupe de contacts à partir de tous les contacts Outlook avec un titre de poste spécifique

Afin de communiquer plus facilement avec les contacts ayant un intitulé de poste spécifique, vous pouvez créer rapidement un groupe de contacts à partir de ces contacts. Maintenant, dans cet article, nous allons partager avec vous une méthode rapide.

Si vous envoyez fréquemment des e-mails, des tâches ou des invitations à des réunions par lots aux contacts ayant un titre de poste spécifique, il sera beaucoup plus pratique de créer un groupe de contacts à partir d'eux. Généralement, de manière standard, vous devez d'abord créer un nouveau groupe de contacts, puis ajouter des contacts au groupe en tant que membres un par un. C'est un peu gênant. Par conséquent, dans ce qui suit, nous vous apprendrons un moyen beaucoup plus rapide de l'obtenir.

Créer un groupe de contacts à partir de tous les contacts avec un titre de poste spécifique

1. Dans un premier temps, dans un dossier Contacts, sélectionnez un contact qui a le titre de poste spécifique.
2. Ensuite, appuyez sur "Alt + F11" pour accéder à l'éditeur Outlook VBA.
3. Ensuite, copiez le code VBA suivant dans un module ou un projet vide.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. Après cela, déplacez le curseur dans le premier sous-programme.
5. Enfin, appuyez sur la touche "F5" pour exécuter cette macro.
6. Une fois la macro terminée, un nouveau groupe de contacts s'affichera. Il contient tous les contacts avec le même intitulé de poste que le contact sélectionné à l'étape 1.

Protégez efficacement les données Outlook

Bien qu'Outlook soit riche en fonctionnalités, il ne peut pas se débarrasser du fait qu'il est vulnérable. Donc, si vous ne voulez pas perdre vos précieuses données Outlook, vous devez faire des efforts pour les protéger. Par exemple, vous devez effectuer des sauvegardes des données Outlook à intervalles réguliers. De plus, si cela est abordable, il est recommandé d'avoir un outil de réparation PST de pointe, tel que DataNumen Outlook Repair, Qui peut réparer la TVP données en un tour de main.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris sql corrompu et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com