Comment convertir par lots et joindre plusieurs documents Word en tant que PDF Fichiers vers un e-mail Outlook

Il est facile de joindre un document Word en tant que PDF fichier à un e-mail Outlook. Cependant, si vous souhaitez joindre plusieurs documents Word en tant que PDF fichiers à un e-mail, vous pouvez lire cet article. Ici, nous allons vous montrer une méthode pour l'obtenir par lots.

Pour joindre un document Word en tant que PDF Pour envoyer un fichier par e-mail Outlook, ouvrez d'abord le document Word et cliquez sur le menu « Fichier ». Ensuite, sélectionnez l'onglet « Enregistrer et envoyer », où se trouve le bouton « Envoyer au format PDF », comme illustré dans la capture d'écran ci-dessous.

Ainsi, il est assez simple de joindre un document Word comme PDF à un e-mail. Mais, si vous souhaitez convertir et joindre plusieurs documents Word en tant que PDF fichiers à un e-mail, vous feriez mieux d'utiliser la méthode suivante. Il peut vous permettre de l'accomplir en vrac.

Convertissez et joignez plusieurs documents Word en tant que PDF Fichiers vers un e-mail

1. Pour commencer, rassemblez les documents Word souhaités dans le même dossier Windows.
2. Ensuite, lancez le programme Outlook.
3. Ensuite, copiez le code suivant dans un projet ou un module inutilisé.

Dim objMail As Outlook.MailItem

Sub BatchAttachMultipleWordDocumentsAsPDFToEmail()
    Dim objShell As Object
    Dim objWindowsFolder As Object
    Dim strWindowsFolder As String

    Set objMail = Outlook.Application.CreateItem(olMailItem)

    'Select the specific Windows folder
    Set objShell = CreateObject("Shell.Application")
    Set objWindowsFolder = objShell.BrowseForFolder(0, "Select a Windows folder:", 0, "")

    If Not objWindowsFolder Is Nothing Then
       strWindowsFolder = objWindowsFolder.self.Path & "\"

       Call ProcessFolders(strWindowsFolder)

       objMail.Display
    End If
End Sub

Sub ProcessFolders(strPath As String)
    Dim objFileSystem As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim objWordApp As Word.Application
    Dim objWordDocument As Word.Document
    Dim strDocumentName As String
    Dim strPDF As String

    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFileSystem.GetFolder(strPath)

    For Each objFile In objFolder.Files
        strFileExtension = objFileSystem.GetExtensionName(objFile)
        If LCase(strFileExtension) = "doc" Or LCase(strFileExtension) = "docx" Then
           Set objWordApp = CreateObject("Word.Application")
           Set objWordDocument = objWordApp.Documents.Open(objFile.Path)

           'Convert document to pdf
           strDocumentName = Left(objWordDocument.Name, (Len(objWordDocument.Name) - Len(strFileExtension)) - 1)
           strPDF = strPath & strDocumentName & ".pdf"
           objWordDocument.ExportAsFixedFormat strPDF, wdExportFormatPDF

           objWordDocument.Close False

           'Attach the pdf to email
           objMail.Attachments.Add strPDF

           Kill strPDF
        End If
    Next

    'Process all folders and subfolders
    If objFolder.SubFolders.Count > 0 Then
       For Each objSubfolder In objFolder.SubFolders
           If ((objSubfolder.Attributes And 2) = 0) And ((objSubfolder.Attributes And 4) = 0) Then
              ProcessFolders (objSubfolder.Path)
           End If
       Next
    End If
End Sub

4. Après cela, déplacez le curseur dans le premier sous-programme.
5. Ensuite, appuyez sur "F5" pour exécuter cette macro immédiatement.
6. Dans la petite boîte de dialogue contextuelle, sélectionnez le dossier Windows dans lequel les documents Word source sont stockés.
7. Aussitôt, un nouvel e-mail sera créé, dans lequel vous pourrez voir la pièce jointe PDF fichiers, comme l'hôte d'écran suivant.

En proie à des problèmes d'Outlook

Êtes-vous dérangé par divers problèmes Outlook ? Par exemple, Outlook est fréquemment bloqué dans l'état "ne répond pas" ou le fichier Outlook PST devient inaccessible, etc. En général, vous pouvez d'abord essayer l'outil de réparation de la boîte de réception, Scanpst, pour résoudre les problèmes PST. Pourtant, parfois, les problèmes peuvent dépasser ce que l'outil intégré peut faire. Par conséquent, vous feriez mieux de garder à proximité un utilitaire externe plus puissant, tel que DataNumen Outlook Repair.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris réparation sql et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com