Comment désactiver automatiquement les hyperliens dans les e-mails Outlook entrants provenant d'expéditeurs inconnus

Afin de bloquer les liens malveillants, vous feriez mieux de configurer votre Outlook pour désactiver automatiquement les hyperliens dans les e-mails entrants provenant d'expéditeurs inconnus. Cet article révélera un morceau de codes VBA qui peut vous aider à l'obtenir comme un bouchon.

De nombreux utilisateurs se sont plaints que des virus transmis par courrier électronique attaquaient leur fichier Outlook. Le plus souvent, c'est parce qu'ils font facilement confiance aux e-mails des expéditeurs inconnus. Alors ils téléchargent ou cliquent sur les hyperliens dans les mails. Maintenant, ci-après, nous partagerons une méthode. Il est capable de laisser Outlook désactiver automatiquement les hyperliens des e-mails entrants provenant d'expéditeurs inconnus. Si vous avez de tels besoins, veuillez lire la suite pour obtenir plus de détails.

Désactiver automatiquement les hyperliens dans les e-mails entrants d'expéditeurs inconnus

1. Pour commetart, dans Outlook, allez dans l'éditeur VBA par "Alt + F11".
2. Ensuite, dans le nouvel écran, ajoutez l'objet "MS VBScript Regular Expressions" selon le post "Comment ajouter une bibliothèque d'objetsrary Référence dans VBA" .
3. Ensuite, copiez et collez le code suivant dans le projet "ThisOutlookSession".

Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInboxItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

'Occurs when new mail arrives in your Inbox
Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As MailItem
    Dim objContacts As Outlook.Items
    Dim strFilter As String
    Dim objFoundContact As Outlook.ContactItem
    Dim bUnknownSender As Boolean
    Dim objRegExp As Object
    Dim objFoundResults As Object
    Dim i, n As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Check if the sender is in your default Contact folder
       Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items
       For i = 1 To 3
           strFilter = "[Email" & i & "Address] = " & objMail.SenderEmailAddress
           Set objFoundContact = objContacts.Find(strFilter)
           If Not (objFoundContact Is Nothing) Then
              bUnknownSender = False
              Exit For
           End If
       Next
       If objFoundContact Is Nothing Then
          bUnknownSender = True
       End If
 
       'If the sender is unknown
       If bUnknownSender = True Then
          'Find the urls within "<a href=" tags in HTMLbody of Mail
          Set objRegExp = CreateObject("vbscript.RegExp")
          With objRegExp
               .Pattern = "<?href\s*=\s*[""'].+?[""'][^>]*?"
               .IgnoreCase = True
               .Global = True
          End With
 
          If objRegExp.Test(objMail.HTMLBody) Then
             Set objFoundResults = objRegExp.Execute(objMail.HTMLBody)
             For n = 1 To objFoundResults.Count
                 'Disable the hyperlinks in HTMLbody
                 objMail.HTMLBody = Replace(objMail.HTMLBody, objFoundResults.Item(n - 1).Value, "")
             Next
          End If
 
          'Save the mail
          objMail.Save
       End If
    End If
End Sub

4. Après cela, activez cette macro soit par restart Outlook ou en appuyant sur la touche « F5 » dans « Application_Startup" sous-programme.
5. Depuis lors, chaque fois qu'un e-mail provenant de l'expéditeur qui n'est pas stocké dans le dossier Contact par défaut entre dans la boîte de réception, Outlook désactive automatiquement les liens hypertexte qu'il contient.

Plusieurs questions de nécessité dans la protection Outlook

Comme Outlook est susceptible d'être endommagé, il est assez difficile de sauvegarder le fichier Outlook. Ici, nous énumérerons plusieurs éléments indispensables lors de la protection des données Outlook. Tout d'abord, vous devez sauvegarder régulièrement vos données Outlook. De plus, il est essentiel que vous vous méfiiez de tous les risques potentiels, comme les pièces jointes malveillantes ou les hyperliens. Enfin, vous devez préparer à l'avance un puissant outil de correction d'Outlook, comme DataNumen Outlook Repair. Cela vous sera sûrement utile lorsque vous en aurez besoin réparer la TVP fichier mais l'outil de réparation de la boîte de réception prouve l'échec.

Introduction de l'auteur:

Shirley Zhang est une experte en récupération de données dans DataNumen, Inc., qui est le leader mondial des technologies de récupération de données, y compris mdf endommagé et produits logiciels de réparation Outlook. Pour plus d'informations, visitez www.datanumen.com